⟦fb95448c7⟧

E3 Source Code



separate (Maze)
----------------------------------------------------------------------
--
--                New_maze : create a new maze
--
--                      written by
--
--                   Edmond Schonberg
--
--                      Ada Project
--                   Courant Institute
--                  New York University
--                   251 Mercer Street
--                New York, New York  10012
--
-----------------------------------------------------------------------

-- with Random_Numbers;
-- use Random_Numbers;
-- with System;
-- separate (Maze)

procedure New_Maze (Start, Goal : Position; Num_Lines : Integer) is
    -- create a new maze with a given number of paths, including two long ones
    -- that lead to source and destination.
    Pos : Position;
    D : Direction;
    L : Integer;

    task type Liner is
        -- one is created for each path.
        entry Draw (Pos : Position; Dir : Direction; Len : Integer);
    end Liner;

    type New_Liner is access Liner;
    Next_Line : New_Liner;

    function Max_Len (P : Position; D : Direction) return Integer is
        -- establish distance from any point to boundary,
        -- along a given direction.
    begin
        case D is
            when Up =>
                return P.Row;
            when Right =>
                return (80 - P.Col);
            when Down =>
                return (23 - P.Row);
            when Left =>
                return P.Col;
        end case;

    end Max_Len;
    task body Liner is
        P : Position;
        D : Direction;
        L : Integer;
    begin
        accept Draw (Pos : Position; Dir : Direction; Len : Integer) do
            P := Pos;
            D := Dir;
            L := Len;
        end Draw;
        for I in 1 .. L loop
            Putc (' ', P.Row, P.Col);
            Dist (P.Row, P.Col) := Max_Dist;
            P := Next_Pos (P, D);
        end loop;
    end Liner;

begin
    Clear;
    -- case System.System_Name is
    --   when System.Pc_Dos =>
    --     Fill_Screen (Ascii.Si);
    --  when others =>
    Fill_Screen ('#');
    -- end case;
    Pos := Start;              -- first path starts at source.
    D := Up;                    -- which is always on bottom row.
    L := 20;
    for I in 1 .. Num_Lines loop
        -- create the right number of tasks, and start each at a random posi-
        -- tion, going in a random direction towards the boundary.
        Next_Line := new Liner;
        Next_Line.Draw (Pos, D, L);
        Pos := (2 * (1 + Random_Int (11)), 2 * (1 + Random_Int (38)));
        D := Direction'Val (Random_Int (40) mod 4);
        L := Max_Len (Pos, D);
        L := L / 2 + Random_Int (L / 4);
    end loop;
    -- One more for path leading to destination. (always on top row).
    Next_Line := new Liner;
    Next_Line.Draw (Goal, Down, 22);
exception
    when Storage_Error | Program_Error =>
        Puts ("unable to create new tasks. Try simpler maze.", 23, 1);

end New_Maze;
DataMuseum.dk

Rational R1000/400

⟦fb95448c7⟧ Ada Source

Derivation

E3 Source Code

E3 Meta Data
