DataMuseum.dk

top - metrics - download

    Length: 3518 (0xdbe)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Find_Unit.Build_Ada_Compilation_Unit)
procedure Generic_Unit_Spec (Current_Unit : in out
                                Compilation_Unit.Ada_Compilation_Unit) is
    --==============================================================
    -- This procedure builds the next part of the grammar for an   =
    -- Ada compilation unit. Based on the next token, we will      =
    -- complete different productions. At present, we are parsing  =
    -- a generic specification. This procedure will determine      =
    -- which kind of specification. If a syntax error is found,    =
    -- then the exception Build_Syntax_Error will be raised.       =
    -- The grammar :                                               =
    --               <Generic_Unit_Spec> =                         =
    --                  'PACKAGE' <id> 'IS' <Package_Spec> |       =
    --                  'PROCEDURE' <Subprogram_Spec_Tail> |       =
    --                  'FUNCTION' <Subprogram_Spec_Tail>          =
    --                                                             =
    -- written  by  GER  with  help  from  b2  and  JM             =
    -- May 1985  at EVB Software Engineering                       =
    --==============================================================

    Current_Token : Token_Package.Token;
    -- the current token read from the ada source code file

begin
    -- Generic_Unit_Spec

    -- parse either a package specification, a procedure
    -- specification, or a function specification

    Get_Next_Significant_Token (Significant_Token => Current_Token,
                                Current_Unit => Current_Unit);

    case Token_Package.Value_Of (Current_Token) is
        when Token_Package.Package_Token =>
            Compilation_Unit.Add_Token_To_Compilation_Unit
               (Token_To_Add => Current_Token, Unit_To_Add_To => Current_Unit);

            -- Get the package name identifier

            Get_Next_Significant_Token (Significant_Token => Current_Token,
                                        Current_Unit => Current_Unit);

            if Token_Package.Class_Of (Current_Token) =
               Token_Package.Identifier then
                Compilation_Unit.Add_Token_To_Compilation_Unit
                   (Token_To_Add => Current_Token,
                    Unit_To_Add_To => Current_Unit);
            else

                -- Not part of the legal Ada grammar

                raise Build_Syntax_Error;
            end if;

            -- Get the 'is' for this package

            Get_Next_Significant_Token (Significant_Token => Current_Token,
                                        Current_Unit => Current_Unit);

            if Token_Package.Value_Of (Current_Token) =
               Token_Package.Is_Token then
                Compilation_Unit.Add_Token_To_Compilation_Unit
                   (Token_To_Add => Current_Token,
                    Unit_To_Add_To => Current_Unit);
            else

                -- Not part of the legal Ada grammar

                raise Build_Syntax_Error;
            end if;

            Package_Spec (Current_Unit => Current_Unit);

        when Token_Package.Procedure_Token | Token_Package.Function_Token =>
            Compilation_Unit.Add_Token_To_Compilation_Unit
               (Token_To_Add => Current_Token, Unit_To_Add_To => Current_Unit);
            Subprogram_Spec_Tail (Current_Unit => Current_Unit);
        when others =>
            raise Build_Syntax_Error;
    end case;

end Generic_Unit_Spec;