DataMuseum.dk

top - metrics - download

    Length: 3275 (0xccb)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

with Log;
with Errors;
with Queue;
with Profile;
with Printer;
with Subtypes;
use Subtypes;
with Arguments;
with Pathnames;
with Assertions;
with Debug_Tools;
with Format_Release_Notice;
procedure Print_Release_Notice (For_Catalog : in Simple_Name := "<DEFAULT>";
                                This_Version : in Simple_Name := "<DEFAULT>";
                                Reformat : in Boolean := True;
                                Response : in String := "<PROFILE>") is
    --
    Old_Response_Profile : Profile.Response_Profile := Profile.Get;
    New_Response_Profile : Profile.Response_Profile := Profile.Value (Response);
    --
    package Error is new Errors  
                            (Old_Response_Profile, New_Response_Profile,
                             "Print_Release_Notice");
    --
    function Not_Already_Formatted
                (This_Version : in Full_Name) return Boolean is
    begin
        Assertions.Assert_Has_No_Formatted_Release_Notice (This_Version);
        return (True);
        --
    exception
        when others =>
            return (False);
            --
    end Not_Already_Formatted;
    --
begin
    Profile.Set (New_Response_Profile);
    Log.Put_Line ("[Print_Release_Notice (For_Catalog => """ &
                  For_Catalog & """, This_Version => """ & This_Version &
                  """, Reformat => " & Boolean'Image (Reformat) &
                  ", Response => """ & Response & """)]",
                  Profile.Auxiliary_Msg);
    declare
        The_Version : constant Full_Name :=
           Arguments.Version_From (For_Catalog, This_Version);
    begin  
        if ((Reformat) or else (Not_Already_Formatted (The_Version))) then
            if (Not_Already_Formatted (The_Version)) then
                Log.Put_Line ("Release notice is not already formatted");
            end if;
            begin
                Format_Release_Notice (For_Catalog, This_Version,
                                       Response => "PROPAGATE," & Response);
                --
            exception
                when others =>
                    Error.Report ("Formatting failed, quitting",
                                  Nested => True);
            end;
        end if;
        Log.Put_Line ("Sending formatted release notice to printer");
        Queue.Print (Name =>
                        Pathnames.Formatted_Release_Notice_For (The_Version),
                     Options => Printer.Default_Options_For (The_Version));
    end;
    Log.Put_Line
       ("[end of Print_Release_Notice operation--no error(s) detected]");
    Profile.Set (Old_Response_Profile);
    --
exception
    when Arguments.Invalid_Catalog =>
        Error.Report ("Specified catalog is invalid");
    when Arguments.Invalid_Version =>
        Error.Report ("Specified version is invalid");
    when Arguments.Io_Failure =>
        Error.Report ("Can't find default(s)--run ""Catalog.Set_Defaults""");
    when Printer.Io_Failure =>
        Error.Report ("Can't find printer defaults");
    when Error.Propagate =>
        raise;
    when Error.Quit =>
        null;
    when others =>
        Error.Report ("EXCEPTION: " & Debug_Tools.Get_Exception_Name,
                      Profile.Exception_Msg);
        --
end Print_Release_Notice;