DataMuseum.dk

top - metrics - download

    Length: 3067 (0xbfb)
    Types: TextFile
    Names: »rational«

└─⟦6ac9a67ca⟧ Bits:30000548 8mm tape, Rational 1000, access 1_0_1
    └─⟦78f173837⟧ »DATA« 
        └─⟦687a7d38f⟧ 
└─⟦d10a02448⟧ Bits:30000409 8mm tape, Rational 1000, ENVIRONMENT, D_12_7_3
    └─⟦fc9b38f02⟧ »DATA« 
        └─⟦687a7d38f⟧ 
            └─⟦76eb391d8⟧ 
                └─⟦56d8da70c⟧ 
                    └─⟦this⟧ »bin/rational« 

TextFile

#! /bin/csh -f


set argv0=$0
set rahome=$argv0:h
set raname=$argv0:t

# Run the true script, making sure it is not running a link

set lsinfo = `/bin/ls -lg $argv0 | grep '^[lL]'`
if ($status == 0) then
   exec `echo $lsinfo | awk '{print $11}'` $argv[*]
endif


# Figure out the value of ACCESSHOME

if ($rahome == $raname) then
   set rahome = ''
endif

if ($rahome =~ */bin) then
   set rahome = $rahome:h
endif

set current_dir = $cwd
# Quotes around $current_dir prevents Divide by 0 error, running in /
if ("$current_dir" =~ */bin) then
   set current_dir = $current_dir:h
endif

if ($rahome =~ /*) then
   setenv ACCESSHOME $rahome
else if ((-e ./bin/rational) || (-e ./rational)) then
   setenv ACCESSHOME $current_dir
else if ((-e $rahome/bin/rational) || (-e $rahome/rational)) then
   setenv ACCESSHOME $current_dir/$rahome
endif

# Setup RA to point to the right application defaults

setenv XAPPLRESDIR $ACCESSHOME/app-defaults

# Figure out the platform that it is going to run in

set platform = `uname -m`
set platform_os = `uname`

# Make sure Rational Access has fonts installed

set flag = "f"
set Display = ""
foreach f ($argv[*])
    if ($flag == "t") then
       set Display = $f
       break
    endif
    if ("$f" == "-display") set flag = "t"
end

# Use the display specified by command line

if ($Display != "") setenv DISPLAY $Display

# Check to see whether Rational Access fonts are not installed
# If not, try installing them.

if (`xlsfonts -display xxxxx |& awk '$1 == "xlsfonts:" {print $2}'` != "Command") then

set fonts = `xlsfonts |& egrep '(xlsfonts:|fixed-screen-|cairo-|icon-|parker-|plunk)'`

if (`echo $fonts | grep 'xlsfonts:' | wc -l` != "0") then
   echo "rational:  unable to open display $DISPLAY"
   exit 1
endif 

if (`echo $fonts | grep 'fixed-screen' | wc -l` == "0" || \
    `echo $fonts | grep 'cairo' | wc -l` == "0" || \
    `echo $fonts | grep 'icon' | wc -l` == "0" || \
    `echo $fonts | grep 'parker' | wc -l` == "0" || \
    `echo $fonts | grep 'plunk' | wc -l` == "0") then
   set server = `xdpyinfo |& awk '$1 == "vendor" && $2 == "string:"  { line = $0 } END { print line }'`
   if ($server[3] == "MIT" && $server[4] == "X" && $server[5] == "Consortium") then
       xset fp+ $ACCESSHOME/fonts/SPARC_MIT
   else if ($server[3] == "X11/NeWS") then
       xset fp+ $ACCESSHOME/fonts/SPARC_NeWS
   else if ($server[3] == "International" && $server[4] == "Business" && \
        $server[5] == "Machines") then
       xset fp+ $ACCESSHOME/fonts/RS6000
   else
       echo "RA: Unknown server, unable to find Rational Access fonts"
   endif
endif

else
   echo Unable to find xlsfonts to check for font availability.  
   echo Maybe running Rational Access without font visibility.
endif


if ( $platform_os == "AIX" ) then
   set binary = $ACCESSHOME/bin/access-rs6k
else if ( $platform_os == "SunOS" ) then
   set binary = $ACCESSHOME/bin/access-sparc
else 
   echo "Unpported platform $platform"
   exit 1
endif

if ($?binary && -x $binary) then
   $binary $* &
else
   echo Unable to find $binary
endif