DataMuseum.dk

top - metrics - download

    Length: 3291 (0xcdb)
    Types: TextFile
    Names: »B«

└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─⟦129cab021⟧ »DATA« 
        └─⟦this⟧ 

TextFile

with Expression;
with More_Statements;
with Msg_Report;
with Object;
with Scanner;  
with Unparse_Report;

package body Statements is

    type Node_Structure is
        record
            Rule : Natural range 0 .. 2 := 0;
            Expr : Expression.Node := Expression.Empty_Node;  
            More : More_Statements.Node := More_Statements.Empty_Node;
            Lign : Integer;
        end record;

    procedure Parse (N : in out Node; Error : out Boolean) is
        Failed : Boolean := False;

        use Scanner;
    begin  
        Msg_Report.Information ("I enter in statement's parse");

        N := new Node_Structure;

        N.Lign := Scanner.Line_Number;

        if Expression.Is_First (Scanner.Symbol) then
            N.Rule := 1;
            Expression.Parse (N.Expr, Failed);

            if Scanner.Symbol = L_Unknown then
                Failed := True;
            else
                if Scanner.Symbol /= L_Eof and Scanner.Symbol /= L_Dot then
                    Msg_Report.Syntax_Error
                       ("expected statements separator '.'");
                    Failed := True;
                end if;
            end if;

            if not Failed then
                More_Statements.Parse (N.More, Failed);
            end if;
        else
            case Scanner.Symbol is

                when Scanner.L_Renvoyer =>
                    N.Rule := 2;
                    Scanner.Next;
                    Expression.Parse (N.Expr, Failed);

                when others =>
                    null;

            end case;
        end if;

        Msg_Report.Information ("I leave statement's parse with failed = " &
                                Boolean'Image (Failed));

        Error := Failed;
    end Parse;

    procedure Unparse (N : Node) is

    begin
        case N.Rule is

            when 0 =>
                null;

            when 1 =>
                Expression.Unparse (N.Expr);
                More_Statements.Unparse (N.More);

            when 2 =>
                Unparse_Report.Write ("RENVOYER ");
                Expression.Unparse (N.Expr);

        end case;
    end Unparse;

    function Is_First (T : Scanner.Token) return Boolean is
        use Scanner;
    begin
        return T = L_Renvoyer or else Expression.Is_First (T);
    end Is_First;

    function Interpret (N : Node;
                        Inherited : Object.Reference := Object.Void_Reference)
                       return Object.Reference is
        Result : Object.Reference;
    begin

        Msg_Report.Set_Line_Number (N.Lign);

        Msg_Report.Information ("I enter in statement's interpret");

        case N.Rule is
            when 0 =>
                Result := Inherited;

            when 1 =>
                Result := Expression.Interpret (N.Expr);
                Result := More_Statements.Interpret (N.More, Result);

            when 2 =>
                Result := Expression.Interpret (N.Expr);
        end case;

        Msg_Report.Information ("I leave statement's interpret with result :");
        Msg_Report.Continue
           ("class = " & Object.Class'Image (Object.The_Class (Result)) &
            " ident = " & Integer'Image (Object.Identificator (Result)));

        return Result;
    end Interpret;
end Statements;