DataMuseum.dk

Presents historical artifacts from the history of:

Rational R1000/400 Tapes

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Rational R1000/400 Tapes

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download
Index: B T

⟦2bf435a89⟧ TextFile

    Length: 2731 (0xaab)
    Types: TextFile
    Names: »B«

Derivation

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Named_Block (Current_Compilation_Unit : in out Ada_Compilation_Unit;
                       Program_Unit : in Program_Unit_State_Machine;
                       Halstead : in Halstead_State_Machine;
                       Loc : in Loc_State_Machine;
                       Mccabe : in Mccabe_State_Machine) is

    --===========================================================
    -- Named_Block ::=
    --     [ "DECLARE" Declarative_Part ]
    --     Begin_End_Block [ <IDENTIFIER> ] ";"
    --===========================================================


    Current_Token : Token_Package.Token;
    Is_Begin_Found : Boolean := False;

begin
    -- Named_Block

    case Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) is

        when Token_Package.Declare_Token =>

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            -- increment Halstead DECLARE operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Declare_Halstead));

            Declarative_Part
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe);

        when Token_Package.Begin_Token =>
            null;

        when others =>
            raise Syntax_Error;

    end case;

    Begin_End_Block (Current_Compilation_Unit => Current_Compilation_Unit,
                     Program_Unit => Program_Unit,
                     Halstead => Halstead,
                     Loc => Loc,
                     Mccabe => Mccabe);

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if Token_Package.Class_Of (Current_Token) = Token_Package.Identifier then

        -- increment Halstead operand count
        Halstead.Store_Operand (Halstead_Operand.Definition
                                   (Token_Package.Value_Of
                                       (This_Token => Current_Token)));

        Get_Next_Token (Out_Token => Current_Token,
                        From => Current_Compilation_Unit,
                        Current_Loc => Loc);
    end if;

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Named_Block;