DataMuseum.dk

top - metrics - download

    Length: 2502 (0x9c6)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Use_Clause (Current_Compilation_Unit : in out Ada_Compilation_Unit;
                      Program_Unit : in Program_Unit_State_Machine;
                      Halstead : in Halstead_State_Machine;
                      Loc : in Loc_State_Machine;
                      Mccabe : in Mccabe_State_Machine) is

    --================================================================
    -- USE counts as one LOC data daclaration
    -- Use_Clause ::= "USE" Expanded_Name { "," Expanded_Name } ";"
    --================================================================

    Is_Semicolon_Found : Boolean := False;
    Current_Token : Token_Package.Token;

begin
    -- Use_Clause

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);
    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Use_Token) then
        raise Syntax_Error;
    end if;
    -- increment LOC data declaration count
    Loc.Change_Data_Declarations_Count;

    -- increment Halstead USE operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Use_Halstead));

    Find_Semicolon:
        -- repeat until Current_Token = ';'
        loop

            Expanded_Name (Current_Compilation_Unit => Current_Compilation_Unit,
                           Program_Unit => Program_Unit,
                           Halstead => Halstead,
                           Loc => Loc,
                           Mccabe => Mccabe);
            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);
            case Token_Package.Value_Of (Current_Token) is

                when Token_Package.Comma_Token =>
                    -- increment Halstead COMMA operator count
                    Halstead.Store_Operator
                       ((Kind => Halstead_Operator.Comma_Halstead));

                when Token_Package.Semicolon_Token =>
                    -- increment Halstead SEMICOLON operator count
                    Halstead.Store_Operator
                       ((Kind => Halstead_Operator.Semicolon_Halstead));

                    Is_Semicolon_Found := True;

                when others =>
                    raise Syntax_Error;

            end case;
            exit Find_Semicolon when Is_Semicolon_Found;

        end loop Find_Semicolon;

end Use_Clause;