DataMuseum.dk

top - metrics - download

    Length: 3304 (0xce8)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Exception_Choice
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --===================================================================
    -- Exception_Choice ::=
    --      "WHEN" Expanded_Name { ( "|" | "!" ) Expanded_Name } "=>"
    --         Sequence_Of_Statements
    --===================================================================

    Current_Token : Token_Package.Token;
    -- token being processed

    No_More_Expanded_Names : Boolean := False;
    -- indicates the last name was reached

begin
    -- Exception_Choice

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.When_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead WHEN operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.When_Halstead));

    -- increment McCabe PI
    Mccabe.Change_Pi;

    Process_Expanded_Names:
        -- repeat for every Name
        loop

            Expanded_Name (Current_Compilation_Unit => Current_Compilation_Unit,
                           Program_Unit => Program_Unit,
                           Halstead => Halstead,
                           Loc => Loc,
                           Mccabe => Mccabe);

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);
            case Token_Package.Value_Of (Current_Token) is

                when Token_Package.Vertical_Bar_Token =>
                    -- increment Halstead VERTICAL_BAR operator count
                    Halstead.Store_Operator
                       ((Kind => Halstead_Operator.Vertical_Bar_Halstead));

                    -- increment McCabe predicates count
                    Mccabe.Change_Pi;

                when Token_Package.Exclamation_Mark_Token =>
                    -- increment Halstead EXCLAMATION_MARK operator count
                    Halstead.Store_Operator
                       ((Kind => Halstead_Operator.Exclamation_Mark_Halstead));

                    -- increment McCabe predicates count
                    Mccabe.Change_Pi;

                when Token_Package.Arrow_Token =>
                    -- increment Halstead ARROW operator count
                    Halstead.Store_Operator
                       ((Kind => Halstead_Operator.Arrow_Halstead));

                    -- no more choices
                    No_More_Expanded_Names := True;

                when others =>
                    raise Syntax_Error;

            end case;

            exit Process_Expanded_Names when No_More_Expanded_Names;

        end loop Process_Expanded_Names;

    Sequence_Of_Statements
       (Current_Compilation_Unit => Current_Compilation_Unit,
        Program_Unit => Program_Unit,
        Halstead => Halstead,
        Loc => Loc,
        Mccabe => Mccabe);

end Exception_Choice;