DataMuseum.dk

top - metrics - download

    Length: 4685 (0x124d)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Function_Unit (Current_Compilation_Unit : in out Ada_Compilation_Unit;
                         Program_Unit : in Program_Unit_State_Machine;
                         Halstead : in Halstead_State_Machine;
                         Loc : in Loc_State_Machine;
                         Mccabe : in Mccabe_State_Machine) is

    --=====================================================================
    -- Program unit kind is FUNCTION_BODY, FUNCTION_SPECIFICATION, or
    -- FUNCTION_BODY_STUB.
    -- Function_Unit ::=
    --   Function_Specification
    --      [ "IS" ( Common_Body [ Designator ] | "SEPARATE" ) ] ";"
    --=====================================================================

    Current_Token : Token_Package.Token;
    Parameters_Count : Natural := 0;
    Unit_Name : Program_Unit_Name;

begin
    -- Function_Unit

    Function_Specification
       (Current_Compilation_Unit => Current_Compilation_Unit,
        Program_Unit => Program_Unit,
        Halstead => Halstead,
        Loc => Loc,
        Mccabe => Mccabe,
        Unit_Name => Unit_Name,
        Formal_Parameters_Count => Parameters_Count);

    -- set program unit name
    Program_Unit.Store_Program_Unit_Name (The_Program_Unit_Name => Unit_Name);

    --** changed 11/13/85 by J. Margono
    --** reason: Constraint_Error was raised if Parameters_Count = 0
    if Parameters_Count > 0 then
        -- change LOC data declaration count
        Loc.Change_Data_Declarations_Count
           (The_Amount_To_Change => Parameters_Count);
        -- change Halstead paramaters count
        Halstead.Change_Parameters_Count
           (The_Amount_To_Change => Parameters_Count);
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    case Token_Package.Value_Of (Current_Token) is

        when Token_Package.Is_Token =>

            -- increment Halstead FUNCTION_IS operator count
            Halstead.Store_Operator
               ((Kind => Halstead_Operator.Function_Is_Halstead));

            if Token_Package.Value_Of (Peek
                                          (From => Current_Compilation_Unit)) =
               Token_Package.Separate_Token then

                Get_Next_Token (Out_Token => Current_Token,
                                From => Current_Compilation_Unit,
                                Current_Loc => Loc);

                -- set program unit kind to FUNCTION_BODY_STUB
                Program_Unit.Store_Kind_Of_Program_Unit
                   (The_Kind_Of_Program_Unit => Function_Body_Stub);

                -- increment Halstead SEPARATE operator count
                Halstead.Store_Operator
                   ((Kind => Halstead_Operator.Separate_Halstead));

            else

                -- set program unit kind to FUNCTION_BODY
                Program_Unit.Store_Kind_Of_Program_Unit
                   (The_Kind_Of_Program_Unit => Function_Body);

                Common_Body
                   (Current_Compilation_Unit => Current_Compilation_Unit,
                    Program_Unit => Program_Unit,
                    Halstead => Halstead,
                    Loc => Loc,
                    Mccabe => Mccabe);

                if "/=" (Token_Package.Value_Of
                            (Peek (From => Current_Compilation_Unit)),
                         Token_Package.Semicolon_Token) then

                    Designator (Current_Compilation_Unit =>
                                   Current_Compilation_Unit,
                                Program_Unit => Program_Unit,
                                Halstead => Halstead,
                                Loc => Loc,
                                Mccabe => Mccabe,
                                Unit_Name => Unit_Name);

                end if;

            end if;
            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

        when Token_Package.Semicolon_Token =>

            -- set program unit kind to FUNCTION_SPECIFICATION
            Program_Unit.Store_Kind_Of_Program_Unit
               (The_Kind_Of_Program_Unit => Function_Specification);

        when others =>
            raise Syntax_Error;

    end case;

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Function_Unit;