DataMuseum.dk

top - metrics - download

    Length: 4889 (0x1319)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Generic_Subprogram_Or_Package_Specification
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --=========================================================
    -- Generic_Subprogram_Or_Package_Specification ::=
    --     Procedure_Spefication ";"
    --   | Function_Specification ";"
    --   | Package_Specification
    --=========================================================

    Unit_Name : Program_Unit_Name;
    Parameters_Count : Natural := 0;
    Current_Token : Token_Package.Token;

begin
    -- Generic_Subprogram_Or_Package_Specification

    case Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) is

        when Token_Package.Procedure_Token =>

            -- increment Halstead PROCEDURE operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Procedure_Halstead));

            Procedure_Specification
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe,
                Unit_Name => Unit_Name,
                Formal_Parameters_Count => Parameters_Count);

            -- set program unit kind and name
            Program_Unit.Store_Kind_Of_Program_Unit
               (The_Kind_Of_Program_Unit => Generic_Procedure_Specification);

            -- store program unit name
            Program_Unit.Store_Program_Unit_Name
               (The_Program_Unit_Name => Unit_Name);

            --** added 11/20/85 by J. Margono
            --** reason: to avoid Constraint_Error being raised
            if Parameters_Count > 0 then

                Halstead.Change_Parameters_Count
                   (The_Amount_To_Change => Parameters_Count);

            end if;

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if "/=" (Token_Package.Value_Of (Current_Token),
                     Token_Package.Semicolon_Token) then
                raise Syntax_Error;
            end if;

            -- increment Halstead SEMICOLON operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Semicolon_Halstead));

        when Token_Package.Function_Token =>

            -- increment Halstead FUNCTION operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Function_Halstead));

            Function_Specification
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe,
                Unit_Name => Unit_Name,
                Formal_Parameters_Count => Parameters_Count);

            Program_Unit.Store_Kind_Of_Program_Unit
               (The_Kind_Of_Program_Unit => Generic_Function_Specification);

            Program_Unit.Store_Program_Unit_Name
               (The_Program_Unit_Name => Unit_Name);

            --** added 11/20/85 by J. Margono
            --** reason: to avoid Constraint_Error being raised
            if Parameters_Count > 0 then

                Halstead.Change_Parameters_Count
                   (The_Amount_To_Change => Parameters_Count);

            end if;

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if "/=" (Token_Package.Value_Of (Current_Token),
                     Token_Package.Semicolon_Token) then
                raise Syntax_Error;
            end if;

            -- increment Halstead SEMICOLON operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Semicolon_Halstead));

        when Token_Package.Package_Token =>

            -- set program unit kind to GENERIC_PACKAGE_SPECIFICATION
            Program_Unit.Store_Kind_Of_Program_Unit
               (The_Kind_Of_Program_Unit => Generic_Package_Specification);

            Package_Specification
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe);

        when others =>
            raise Syntax_Error;

    end case;

end Generic_Subprogram_Or_Package_Specification;