DataMuseum.dk

top - metrics - download

    Length: 5042 (0x13b2)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Procedure_Unit
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --==================================================================
    -- Program unit kind is PROCEDURE_BODY, PROCEDURE_SPECIFICATION, or
    -- PROCEDURE_BODY_STUB.

    -- Procedure_Unit ::=
    --   Procedure_Specification
    --   [ "IS" ( Common_Body [ <IDENTIFIER> ] | "SEPARATE" ) ] ";"
    --==================================================================

    Current_Token : Token_Package.Token;
    Parameters_Count : Natural := 0;
    Unit_Name : Program_Unit_Name;

begin
    -- Procedure_Unit

    Procedure_Specification
       (Current_Compilation_Unit => Current_Compilation_Unit,
        Program_Unit => Program_Unit,
        Halstead => Halstead,
        Loc => Loc,
        Mccabe => Mccabe,
        Unit_Name => Unit_Name,
        Formal_Parameters_Count => Parameters_Count);

    --** changed 11/13/85 by J. Margono
    --** reason: Constraint_Error was raised if Parameters_Count = 0
    if Parameters_Count > 0 then
        -- change LOC data declaration count
        Loc.Change_Data_Declarations_Count
           (The_Amount_To_Change => Parameters_Count);
        -- change Halstead paramaters count
        Halstead.Change_Parameters_Count
           (The_Amount_To_Change => Parameters_Count);
    end if;

    -- set program unit name
    Program_Unit.Store_Program_Unit_Name (The_Program_Unit_Name => Unit_Name);

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    case Token_Package.Value_Of (Current_Token) is

        when Token_Package.Is_Token =>

            -- increment Halstead PROCEDURE_IS operator count
            Halstead.Store_Operator
               ((Kind => Halstead_Operator.Procedure_Is_Halstead));

            if Token_Package.Value_Of (Peek
                                          (From => Current_Compilation_Unit)) =
               Token_Package.Separate_Token then

                Get_Next_Token (Out_Token => Current_Token,
                                From => Current_Compilation_Unit,
                                Current_Loc => Loc);

                -- increment Halstead SEPARATE operator count
                Halstead.Store_Operator
                   ((Kind => Halstead_Operator.Separate_Halstead));

                -- set program unit kind to PROCEDURE_BODY_STUB
                Program_Unit.Store_Kind_Of_Program_Unit
                   (The_Kind_Of_Program_Unit => Procedure_Body_Stub);

                Get_Next_Token (Out_Token => Current_Token,
                                From => Current_Compilation_Unit,
                                Current_Loc => Loc);
            else

                -- set program unit kind to PROCEDURE_BODY
                Program_Unit.Store_Kind_Of_Program_Unit
                   (The_Kind_Of_Program_Unit => Procedure_Body);

                Common_Body
                   (Current_Compilation_Unit => Current_Compilation_Unit,
                    Program_Unit => Program_Unit,
                    Halstead => Halstead,
                    Loc => Loc,
                    Mccabe => Mccabe);

                Get_Next_Token (Out_Token => Current_Token,
                                From => Current_Compilation_Unit,
                                Current_Loc => Loc);

                if Token_Package.Class_Of (Current_Token) =
                   Token_Package.Identifier then

                    -- increment Halstead operand count
                    Halstead.Store_Operand
                       (Halstead_Operand.Definition
                           (Token_Package.Value_Of
                               (This_Token => Current_Token)));

                    Get_Next_Token (Out_Token => Current_Token,
                                    From => Current_Compilation_Unit,
                                    Current_Loc => Loc);
                end if;

            end if;

        when Token_Package.Semicolon_Token =>

            -- set program unit kind to PROCEDURE_SPECIFICATION
            Program_Unit.Store_Kind_Of_Program_Unit
               (The_Kind_Of_Program_Unit => Procedure_Specification);

            -- increment Halstead PROCEDURE operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Procedure_Halstead));

        when others =>
            raise Syntax_Error;

    end case;

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Procedure_Unit;