DataMuseum.dk

top - metrics - download

    Length: 4356 (0x1104)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Loop_Statement
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --==============================================
    -- LOOP_Statement ::=
    --     "WHILE" Expression Basic_LOOP_Statement
    --   | "FOR" <IDENTIFIER> "IN" [ "REVERSE" ]
    --         Expression Basic_LOOP_Statement
    --   | Basic_LOOP_Statement
    --==============================================

    Current_Token : Token_Package.Token;

begin
    -- LOOP_Statement

    case Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) is

        when Token_Package.While_Token =>
            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            -- increment Halstead WHILE operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.While_Halstead));

            -- increment McCabe PI
            Mccabe.Change_Pi;

            -- until "LOOP" is found
            Expression (Current_Compilation_Unit => Current_Compilation_Unit,
                        Program_Unit => Program_Unit,
                        Halstead => Halstead,
                        Loc => Loc,
                        Mccabe => Mccabe,
                        Terminate_Tokens =>
                           Set_Of_Tokens'(1 => Token_Package.Loop_Token));

        when Token_Package.For_Token =>

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            -- increment McCabe PI
            Mccabe.Change_Pi;

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if "/=" (Token_Package.Class_Of (Current_Token),
                     Token_Package.Identifier) then
                raise Syntax_Error;
            end if;

            -- increment Halstead operand count
            Halstead.Store_Operand (Halstead_Operand.Definition
                                       (Token_Package.Value_Of
                                           (This_Token => Current_Token)));

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if "/=" (Token_Package.Value_Of (Current_Token),
                     Token_Package.In_Token) then
                raise Syntax_Error;
            end if;

            -- increment Halstead FOR_IN operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.For_In_Halstead));

            if Token_Package.Value_Of (Peek
                                          (From => Current_Compilation_Unit)) =
               Token_Package.Reverse_Token then

                Get_Next_Token (Out_Token => Current_Token,
                                From => Current_Compilation_Unit,
                                Current_Loc => Loc);

                -- increment Halstead REVERSE operator count
                Halstead.Store_Operator
                   ((Kind => Halstead_Operator.Reverse_Halstead));

            end if;

            -- until "LOOP" is found
            Expression (Current_Compilation_Unit => Current_Compilation_Unit,
                        Program_Unit => Program_Unit,
                        Halstead => Halstead,
                        Loc => Loc,
                        Mccabe => Mccabe,
                        Terminate_Tokens =>
                           Set_Of_Tokens'(1 => Token_Package.Loop_Token));

        when others =>
            null;

    end case;

    Basic_Loop_Statement (Current_Compilation_Unit => Current_Compilation_Unit,
                          Program_Unit => Program_Unit,
                          Halstead => Halstead,
                          Loc => Loc,
                          Mccabe => Mccabe);

end Loop_Statement;