DataMuseum.dk

Presents historical artifacts from the history of:

Rational R1000/400 Tapes

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Rational R1000/400 Tapes

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download
Index: T

⟦628db30c0⟧ TextFile

    Length: 2322 (0x912)
    Types: TextFile
    Names: »TINY_SPIRALES«

Derivation

└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─⟦129cab021⟧ »DATA« 
        └─⟦this⟧

TextFile

--
--  Tubes & spirales en tous genres.
--

pour spirale prendre {
  avec pas: n angle: theta.
  tortue baisse_ta_plume.   
  1 a: n repeter: {
    avec l.
    tortue avance:l.
    tortue a_gauche: theta.
    }.
  tortue leve_ta_plume.
  }.

pour polygone prendre {
  avec cotes:n longueur: l.
  pour angle prendre 360/n.
  tortue ton_angle:180.
  tortue baisse_ta_plume.
  n fois: {
    tortue avance:l.
    tortue a_gauche: angle.
    }.
  }.

pour des_polygones prendre {
  avec de:min a:max largeur:l.
  pour x1 prendre (tortue ton_x).
  pour y1 prendre (tortue ton_y).
  min a: max repeter: {
    avec n.
    tortue va_en_x:x1 y:y1.
    polygone cotes:n longueur:l.
    }.
  }.

pour etoile prendre {
  avec arete: longueur.
  tortue a_droite: 90.
  8 fois: {
    tortue a_gauche:135.
    tortue avance: longueur.
    tortue a_droite:90.
    tortue avance: longueur.
    }.
  }.

pour carre prendre {
  avec gauche:g haut:h largeur:l.
  tortue va_en_x:g y:h.
  tortue baisse_ta_plume.
  4 fois: {
    tortue avance:l.
    tortue a_droite:90.
    }.
  }.

pour tube prendre {
  avec x:x y:y taille:t profondeur:p.
  p<=0 si_faux: {
    tortue va_en_x:x y:y.
    polygone cotes:8 longueur:t.
    tortue leve_ta_plume.
    tube x:(x+3) y:(y-3) taille:(t-1) profondeur: (p-1).
    }.
  }.

pour europe prendre {
     tortue va_en_x:(tortue ton_x) - 35 y:(tortue ton_y) - 130.
     tortue ton_angle: 0.
     1 a: 12 repeter: {
            avec i.
            tortue leve_ta_plume.
            tortue avance: 70.
            tortue baisse_ta_plume.
            etoile arete: 10.
            tortue ton_angle: i*30.
     }.
     tortue leve_ta_plume.
}.


stylo va_en_x:140 y:40.
stylo epais.
stylo ecris: "Tourrrrnicoti...". 
1 secondes.
stylo va_en_x:440 y:40.
stylo ecris: "Tourrrrnicoton...".
1 secondes.

tortue ta_taille:1.
tortue va_au_centre.
spirale pas:150 angle:90.

tortue ta_taille:2.
tortue va_au_centre.
europe valeur.

tortue ta_taille:1.
tortue va_en_x:150 y:170.
spirale pas:83 angle:45.

tortue va_en_x:650 y:170.
spirale pas:93 angle:50.

tortue va_en_x:150 y:650.
spirale pas:150 angle:89.

tortue va_en_x:650 y:650.
spirale pas:150 angle:91.

tortue ta_taille:2.
tube x:380 y:700 taille:40 profondeur:35. 

stylo fin.
stylo va_en_x:465 y:790.
stylo ecris: "Cliquez dans la fenetre pour continuer...".