DataMuseum.dk

top - metrics - download

    Length: 3118 (0xc2e)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Renaming_Prefix
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --=============================================
    -- Renaming_Prefix ::=
    --    Procedure_Specification
    --  | Function_Specification
    --  | "PACKAGE" <IDENTIFIER>
    --=============================================

    Current_Token : Token_Package.Token;
    Dummy_Name : Program_Unit_Name;
    --** changed 11/21/85 by J. Margono
    --** reason: Constraint_Error was raised
    Dummy_Count : Natural;

begin
    -- Renaming_Prefix

    case Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) is

        when Token_Package.Procedure_Token =>

            -- increment Halstead PROCEDURE operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Procedure_Halstead));

            Procedure_Specification
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe,
                Unit_Name => Dummy_Name,
                Formal_Parameters_Count => Dummy_Count);

        when Token_Package.Function_Token =>

            -- increment Halstead FUNCTION operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Function_Halstead));

            Function_Specification
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe,
                Unit_Name => Dummy_Name,
                Formal_Parameters_Count => Dummy_Count);

        when Token_Package.Package_Token =>

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            -- increment Haltead PACKAGE operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Package_Halstead));

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if "/=" (Token_Package.Class_Of (Current_Token),
                     Token_Package.Identifier) then
                raise Syntax_Error;
            end if;

            -- increment Halstead operand count
            Halstead.Store_Operand (Halstead_Operand.Definition
                                       (Token_Package.Value_Of
                                           (This_Token => Current_Token)));

        when others =>
            raise Syntax_Error;

    end case;

end Renaming_Prefix;