DataMuseum.dk

top - metrics - download

    Length: 3689 (0xe69)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

with Log;
with Errors;
with Profile;
with Compose;
with Subtypes;
use Subtypes;
with Arguments;
with Pathnames;
with Assertions;
with Debug_Tools;
with Generate_Booklet;
procedure Format_Booklet (For_Catalog : in Simple_Name := "<DEFAULT>";
                          This_Version : in Simple_Name := "<DEFAULT>";
                          Regenerate : in Boolean := True;
                          Response : in String := "<PROFILE>") is
    --
    Old_Response_Profile : Profile.Response_Profile := Profile.Get;
    New_Response_Profile : Profile.Response_Profile := Profile.Value (Response);
    --
    package Error is
       new Errors  
              (Old_Response_Profile, New_Response_Profile, "Format_Booklet");
    --
    function Has_No_Booklet (This_Version : in Full_Name) return Boolean is
    begin
        Assertions.Assert_Has_No_Booklet (This_Version);
        return (True);
        --
    exception
        when others =>
            return (False);
            --
    end Has_No_Booklet;
    --
    procedure Regenerate_The_Booklet_If_Necessary
                 (The_Version : in Full_Name) is
        --
        No_Booklet : constant Boolean := Has_No_Booklet (The_Version);
        --
    begin
        if (Regenerate or else No_Booklet) then
            if (No_Booklet) then
                Log.Put_Line ("Version has no booklet");
            end if;
            begin
                Generate_Booklet (For_Catalog, This_Version,
                                  Response => "PROPAGATE," & Response);
                Assertions.Assert_Has_Booklet (The_Version);
                --
            exception
                when others =>
                    Error.Report ("Booklet generation failed", Nested => True);
            end;
        end if;
    end Regenerate_The_Booklet_If_Necessary;
    --
    procedure Format_The_Booklet (The_Version : in Full_Name) is
    begin
        Log.Put_Line ("Formatting booklet");  
        Compose (Document => Pathnames.Booklet_For (The_Version),
                 Options => "Include => " &
                               Pathnames.Document_Setup_File_For (The_Version),
                 Response => "PROPAGATE," & Response);
        Assertions.Assert_Has_Formatted_Booklet (The_Version);
        --
    exception
        when others =>
            Error.Report ("Booklet formatting failed", Nested => True);
            --
    end Format_The_Booklet;
    --
begin
    Profile.Set (New_Response_Profile);
    Log.Put_Line ("[Format_Booklet (For_Catalog => """ & For_Catalog &
                  """, This_Version => """ & This_Version &
                  """, Regenerate => " & Boolean'Image (Regenerate) &
                  ", Response => """ & Response & """)]",
                  Profile.Auxiliary_Msg);
    declare
        The_Version : constant Full_Name :=
           Arguments.Version_From (For_Catalog, This_Version);
    begin  
        Regenerate_The_Booklet_If_Necessary (The_Version);
        Format_The_Booklet (The_Version);
    end;
    Log.Put_Line ("[end of Format_Booklet operation--no error(s) detected]");
    Profile.Set (Old_Response_Profile);
    --
exception
    when Arguments.Invalid_Catalog =>
        Error.Report ("Specified catalog is invalid");
    when Arguments.Invalid_Version =>
        Error.Report ("Specified version is invalid");
    when Arguments.Io_Failure =>
        Error.Report ("Can't find default(s)--run ""Catalog.Set_Defaults""");
    when Error.Propagate =>
        raise;
    when Error.Quit =>
        null;
    when others =>
        Error.Report ("EXCEPTION: " & Debug_Tools.Get_Exception_Name,
                      Profile.Exception_Msg);
        --
end Format_Booklet;