DataMuseum.dk

top - metrics - download

    Length: 4383 (0x111f)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Package_Specification
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --=================================================================
    -- Package_Specification ::=
    --     "PACKAGE" <IDENTIFIER> "IS"
    --     [ Declarative_Part [ "PRIVATE" Declarative_Part ] ]
    --     "END" [ <IDENTIFIER> ] ";
    --=================================================================

    Current_Token : Token_Package.Token;
    Unit_Name : Program_Unit_Name;

begin
    -- Package_Specification

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Package_Token) then
        raise Syntax_Error;
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Class_Of (Current_Token),
             Token_Package.Identifier) then
        raise Syntax_Error;
    end if;

    -- convert Token_Value to Program_Unit_Name
    Unit_Name := String_To_Name (Token_Package.Value_Of (Current_Token));

    --**
    Program_Unit.Store_Program_Unit_Name (The_Program_Unit_Name => Unit_Name);

    -- increment Halstead operand count
    Halstead.Store_Operand (Halstead_Operand.Definition
                               (Token_Package.Value_Of
                                   (This_Token => Current_Token)));

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Is_Token) then
        raise Syntax_Error;
    end if;

    Declarative_Part (Current_Compilation_Unit => Current_Compilation_Unit,
                      Program_Unit => Program_Unit,
                      Halstead => Halstead,
                      Loc => Loc,
                      Mccabe => Mccabe);

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Private_Token then

        Get_Next_Token (Out_Token => Current_Token,
                        From => Current_Compilation_Unit,
                        Current_Loc => Loc);

        -- increment Halstead PRIVATE operator count
        Halstead.Store_Operator ((Kind => Halstead_Operator.Private_Halstead));

        Declarative_Part (Current_Compilation_Unit => Current_Compilation_Unit,
                          Program_Unit => Program_Unit,
                          Halstead => Halstead,
                          Loc => Loc,
                          Mccabe => Mccabe);
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.End_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead operator PACKAGE_IS_END operator count
    Halstead.Store_Operator ((Kind =>
                                 Halstead_Operator.Package_Is_End_Halstead));

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if Token_Package.Class_Of (Current_Token) = Token_Package.Identifier then

        -- increment Halstead operand count
        Halstead.Store_Operand (Halstead_Operand.Definition
                                   (Token_Package.Value_Of
                                       (This_Token => Current_Token)));

        Get_Next_Token (Out_Token => Current_Token,
                        From => Current_Compilation_Unit,
                        Current_Loc => Loc);
    end if;

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Package_Specification;