DataMuseum.dk

top - metrics - download

    Length: 6063 (0x17af)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Generic_Instantiation
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --========================================================
    -- Generic_Instantiation ::=
    --     ( "PROCEDURE" <IDENTIFIER>
    --     | "FUNCTION" Designator
    --     | "PACKAGE" <IDENTIFIER> )
    --     "IS" "NEW" Expanded_Name [ Aggregate ] ";"
    --========================================================

    Current_Token : Token_Package.Token;
    Actual_Parameters_Count : Natural := 0;
    Unit_Name : Program_Unit_Name;

begin
    -- Generic_Instantiation

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    case Token_Package.Value_Of (Current_Token) is

        when Token_Package.Procedure_Token =>

            -- program unit kind to GENERIC_PROCEDURE_INSTANTIATION
            Program_Unit.Store_Kind_Of_Program_Unit
               (The_Kind_Of_Program_Unit => Generic_Procedure_Instantiation);

            -- increment Halstead PROCEDURE operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Procedure_Halstead));

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if "/=" (Token_Package.Class_Of (Current_Token),
                     Token_Package.Identifier) then
                raise Syntax_Error;
            end if;

            -- convert Token_Value to Program_Unit_Name
            Unit_Name := String_To_Name
                            (Token_Package.Value_Of (Current_Token));

            -- set program unit name
            Program_Unit.Store_Program_Unit_Name
               (The_Program_Unit_Name => Unit_Name);

        when Token_Package.Function_Token =>

            -- program unit kind to GENERIC_FUNCTION_INSTANTIATION
            Program_Unit.Store_Kind_Of_Program_Unit
               (The_Kind_Of_Program_Unit => Generic_Function_Instantiation);

            -- increment Halstead FUNCTION operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Function_Halstead));

            Designator (Current_Compilation_Unit => Current_Compilation_Unit,
                        Program_Unit => Program_Unit,
                        Halstead => Halstead,
                        Loc => Loc,
                        Mccabe => Mccabe,
                        Unit_Name => Unit_Name);

            -- set program unit name
            Program_Unit.Store_Program_Unit_Name
               (The_Program_Unit_Name => Unit_Name);

        when Token_Package.Package_Token =>

            -- program unit kind to GENERIC_PACKAGE_INSTANTIATION
            Program_Unit.Store_Kind_Of_Program_Unit
               (The_Kind_Of_Program_Unit => Generic_Package_Instantiation);

            -- increment Halstead PACKAGE operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Package_Halstead));

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if "/=" (Token_Package.Class_Of (Current_Token),
                     Token_Package.Identifier) then
                raise Syntax_Error;
            end if;

            -- convert Token_Value to Program_Unit_Name
            Unit_Name := String_To_Name
                            (Token_Package.Value_Of (Current_Token));

            -- set program unit name
            Program_Unit.Store_Program_Unit_Name
               (The_Program_Unit_Name => Unit_Name);

        when others =>
            raise Syntax_Error;

    end case;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Is_Token) then
        raise Syntax_Error;
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.New_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead IS_NEW operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Is_New_Halstead));

    Expanded_Name (Current_Compilation_Unit => Current_Compilation_Unit,
                   Program_Unit => Program_Unit,
                   Halstead => Halstead,
                   Loc => Loc,
                   Mccabe => Mccabe);

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Left_Parenthesis_Token then

        Aggregate (Current_Compilation_Unit => Current_Compilation_Unit,
                   Program_Unit => Program_Unit,
                   Halstead => Halstead,
                   Loc => Loc,
                   Mccabe => Mccabe,
                   Number_Of_Components => Actual_Parameters_Count);

        -- change number of parameters
        Halstead.Change_Parameters_Count
           (The_Amount_To_Change => Actual_Parameters_Count);

    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Generic_Instantiation;