DataMuseum.dk

top - metrics - download

    Length: 3303 (0xce7)
    Types: TextFile
    Names: »V«

└─⟦d10a02448⟧ Bits:30000409 8mm tape, Rational 1000, ENVIRONMENT, D_12_7_3
    └─⟦fc9b38f02⟧ »DATA« 
        └─⟦9b46a407a⟧ 
            └─⟦12c68c704⟧ 
                └─⟦this⟧ 
└─⟦5f3412b64⟧ Bits:30000745 8mm tape, Rational 1000, ENVIRONMENT 12_6_5 TOOLS 
    └─⟦91c658230⟧ »DATA« 
        └─⟦458657fb6⟧ 
            └─⟦220843204⟧ 
                └─⟦this⟧ 

TextFile

with System_Utilities;
with Telnet_Profile;

package Telnet is

    subtype User_Name is String;
    -- As used here, a User_Name is the name of a local user
    -- and session, joined by a '.', for example "CAROL.S_1".

    subtype Machine_Name is String;
    -- The name of a remote machine, to be used by Transport_Name_Map.

    subtype Session_Number is Positive;
    -- A single user may have several Telnet sessions with one remote
    -- machine: they are distinguished by different Session_Numbers.


    procedure Connect (Remote_Machine : Machine_Name :=
                          Telnet_Profile.Remote_Machine;
                       Session : Session_Number := 1;
                       Escape : String := Telnet_Profile.Escape;
                       Escape_On_Break : Boolean :=
                          Telnet_Profile.Escape_On_Break;
                       Terminal : System_Utilities.Port :=
                          System_Utilities.Terminal);

    -- Start or resume a session with the specified Remote_Machine
    -- and Session number.  If such a session already exists, it is
    -- resumed, if not, a new session is started.

    -- If Escape is non-null, and the Escape string is received
    -- from the terminal, then the session will be suspended
    -- and the terminal will be reconnected to the Environment.
    -- If Escape_On_Break is true, then a BREAK signal from the
    -- terminal will likewise escape from the session.

    -- Terminal specifies the local terminal from which you want
    -- to interact with the Remote_Machine.  The default is the
    -- same terminal you're currently logged in on.


    function My_User_Name return User_Name;

    procedure Disconnect (Remote_Machine : Machine_Name :=
                             Telnet_Profile.Remote_Machine;
                          Session : Session_Number := 1;
                          User : User_Name := Telnet.My_User_Name);
    -- Disconnect the Telnet session with the specified Remote_Machine
    -- and Session number which was started by the specified User.
    -- If no such session exists, do nothing.

    procedure Show_Sessions (User : User_Name := Telnet.My_User_Name);
    -- Show a table of existing sessions for the specified User.
    -- If User => "?", show existing sessions for all users.

    procedure Send (Data : String := Telnet_Profile.Escape;
                    Remote_Machine : Machine_Name :=
                       Telnet_Profile.Remote_Machine;
                    Session : Session_Number := 1);
    -- If a session to the specified Remote_Machine and Session
    -- exists, send the specified Data on it.  To the remote
    -- machine, it looks as though the data came from the terminal.
    -- If no such session exists, do nothing.

    procedure Send_Break (Remote_Machine : Machine_Name :=
                             Telnet_Profile.Remote_Machine;
                          Session : Session_Number := 1);
    -- If a session to the specified Remote_Machine and Session
    -- exists, send a break signal on it.  To the remote machine,
    -- it looks as though the break signal came from the terminal.
    -- If no such session exists, do nothing.

    pragma Subsystem (Ftp_Interface, Private_Part => Closed);
    pragma Module_Name (4, 3544);
end Telnet;