DataMuseum.dk

top - metrics - download

    Length: 3748 (0xea4)
    Types: TextFile
    Names: »TINY_DEBUT«

└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─⟦129cab021⟧ »DATA« 
        └─⟦this⟧ 

TextFile

--
--  tableau initial de la demo.
--

pour baratin prendre {
   stylo moyen.
   stylo ton_x:50 ton_y:50.
   stylo ecris: "Toc Toc, Bonjour c'est moi,  j'vous fais une cascade...".
   2 secondes.
   stylo epais.
   1 a: 25 repeter: { avec i.
      stylo ton_x:10 ton_y:100.
      stylo a_droite:i*5.
      stylo en_bas:(i au_carre)/2.
      stylo ecris:"Bienvenue dans l'univers de Tiny_Talk ... ". }.
   2 secondes.
   stylo moyen.
   stylo a_gauche:50.
   stylo en_bas:80.
   stylo ecris: "Bonjour, je m'appelle Tiny_Talk, je suis le petit langage  ".
   stylo en_bas:20.
   stylo ecris: "   avec lequel a ete concue cette demonstration.".
   stylo en_bas:20.
   stylo ecris: "Juste histoire de vous montrer de quoi je suis capable...".
   stylo en_bas:40.
   stylo ecris: "Mais avant de commencer, je tiens a remercier J. Rodrigues et P. Rochefolle,".
   stylo en_bas:20.
   stylo ecris: "   sans qui rien de tout cela n'aurait ete possible.".
   stylo en_bas:40.
   stylo ecris: "Ah, un dernier detail ! Comme vous pouvez le voir sur ce petit billard,".
   stylo en_bas:20.
   stylo ecris: "   bien que tres jeune, je ne suis pas tres rapide. ".
   stylo en_bas:20.
   stylo ecris: "Soyez neanmoins indulgent, car je sais faire de jolies choses... ".
}.

Pour RECTANGLE prendre 
{  Avec GAUCHE: G HAUT: H LARGEUR: LARG HAUTEUR: HAUT .
   TORTUE LEVE_TA_PLUME .
   TORTUE VA_EN_X: G Y: H .
   TORTUE TON_ANGLE: 90 .
   TORTUE BAISSE_TA_PLUME .
   2 FOIS: 
   { 
      TORTUE AVANCE: HAUT .
      TORTUE A_GAUCHE: 90 .
      TORTUE AVANCE: LARG .
      TORTUE A_GAUCHE: 90 .
   } 
}.

Pour BILLARD prendre 
{ 
   Avec LARGEUR: L HAUTEUR: H X: X Y: Y DUREE: CPT_MAX .
   Pour L_MIN prendre X + 2 .
   Pour H_MIN prendre Y + 16 .
   Pour L_MAX prendre X + L - 11 .
   Pour H_MAX prendre Y + H - 5 .
   Pour PAS prendre 3 .
   Pour OLD_X prendre L_MIN + ( ( L_MAX - L_MIN ) / 2 ) .
   Pour OLD_Y prendre H_MIN + ( ( H_MAX - H_MIN ) / 2 ) .
   Pour NEW_X prendre 0 .
   Pour NEW_Y prendre 0 .
   Pour MONTER prendre VRAI .
   Pour DROITE prendre VRAI .
   Pour CPT prendre 0 .
   STYLO VA_EN_X: OLD_X Y: OLD_Y .
   STYLO MOYEN .
   RECTANGLE GAUCHE: X HAUT: Y LARGEUR: L HAUTEUR: H .
   RECTANGLE GAUCHE: X - 10 HAUT: Y - 10 LARGEUR: L + 20 HAUTEUR: H + 20 .
   RECTANGLE GAUCHE: X - 12 HAUT: Y - 12 LARGEUR: L + 24 HAUTEUR: H + 24 .
   TORTUE TA_TAILLE:5.
   TORTUE TON_X:X-12+6 TON_Y:Y+12+H+3.
   TORTUE TON_ANGLE:0.
   TORTUE BAISSE_TA_PLUME.
   TORTUE AVANCE:L+24-3.
   TORTUE A_GAUCHE:90.
   TORTUE AVANCE:H+24-3.
   TORTUE LEVE_TA_PLUME.
   { CPT < CPT_MAX } TANT_QUE_VRAI: 
   { 
      Pour CPT prendre CPT + 1 .
      Pour OK prendre VRAI .
      MONTER SI_VRAI: { Pour NEW_Y prendre OLD_Y - PAS } 
             SI_FAUX: { Pour NEW_Y prendre OLD_Y + PAS }.
      DROITE SI_VRAI: { Pour NEW_X prendre OLD_X + PAS } 
             SI_FAUX: { Pour NEW_X prendre OLD_X - PAS }. 
      (( NEW_X > L_MAX ) | ( NEW_X < L_MIN )) SI_VRAI: 
      { 
         Pour DROITE prendre DROITE INVERSE .
         Pour OK prendre FAUX .
      }.
      (( NEW_Y > H_MAX ) | ( NEW_Y < H_MIN )) SI_VRAI: 
      { 
         Pour MONTER prendre MONTER INVERSE .
         Pour OK prendre FAUX .         
      }.
      OK SI_VRAI: 
      { 
         STYLO VA_EN_X: OLD_X Y: OLD_Y .
         STYLO ECRIS: " " .
         STYLO VA_EN_X: NEW_X Y: NEW_Y.
         STYLO ECRIS: "o" .
         Pour OLD_X prendre NEW_X .
         Pour OLD_Y prendre NEW_Y .
      }.
   }.
   2 SECONDES.
   STYLO ECRIS: " " .
}.

baratin valeur.
10 secondes.
BILLARD LARGEUR: 115 HAUTEUR: 70 X: 50 Y: 710 DUREE: 250 .
stylo va_en_x:350 y:740.
stylo epais.
stylo ecris: "C'est quand vous voulez !".
stylo fin.
stylo va_en_x:465 y:790.
stylo ecris: "Cliquez dans la fenetre pour continuer...".