DataMuseum.dk

top - metrics - download

    Length: 3173 (0xc65)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Tracker.Element_Pkg)
procedure Update_Current is
    -----------------------------------------------------------------------------
    --|
    --|  NAME:  UPDATE_CURRENT
    --|
    --|  OVERVIEW:
    --|    This procedure walks through a group of elements and asks the user
    --|    to update the current size estimate.  If no change is desired, the
    --|    user presses <cr>.  Otherwise he enters the new value for current
    --|    size.
    --|
    --|  EXCEPTIONS HANDLED:
    --|    none
    --|
    --|  HISTORY:
    --|    written by   Bonnie Burkhardt   March 1985
    --|
    -----------------------------------------------------------------------------
    Selection : Integer := 0;
    Quit : Boolean := False;
    El_Ptr : Element_Pointer;
    End_List : Boolean := False;
    Ms_Ptr : Milestone_Pointer;
    Ms_Num : Ms_Num_Type := 1;
    Pr_Ptr : Personnel_Pointer;
    Pr_Initials : Pr_Init_Type := (others => ' ');
    Ss_Ptr : Subsystem_Pointer;
    Ss_Name : Ss_Name_Type := (others => ' ');
    Succeed : Boolean := False;

    procedure Fix_El_Size (El_Ptr : in Element_Pointer) is separate;

begin
    loop
        Selection := Vt100.Print_El_Groups;

        case Selection is
            when 1 =>
                -- all elements
                Start_Walk (El_List);

                loop
                    Walk (El_List, El_Ptr, End_List);
                    exit when End_List;
                    Fix_El_Size (El_Ptr);
                end loop;

            when 2 =>
                -- milestone
                Prompt_Pkg.Existing_Milstone_Number (Quit, Ms_Num);

                if not Quit then
                    Find (Ms_List, Ms_Num, Ms_Ptr, Succeed);
                    Start_Walk (Ms_Ptr.Element_List);

                    loop
                        Walk (Ms_Ptr.Element_List, El_Ptr, End_List);
                        exit when End_List;
                        Fix_El_Size (El_Ptr);
                    end loop;
                end if;

            when 3 =>
                -- person
                Prompt_Pkg.Existing_Person_Initials (Quit, Pr_Initials);

                if not Quit then
                    Find (Pr_List, Pr_Initials, Pr_Ptr, Succeed);
                    Start_Walk (Pr_Ptr.Element_List);

                    loop
                        Walk (Pr_Ptr.Element_List, El_Ptr, End_List);
                        exit when End_List;
                        Fix_El_Size (El_Ptr);
                    end loop;
                end if;

            when 4 =>
                -- subsystem
                Prompt_Pkg.Existing_Subsys_Name (Quit, Ss_Name);

                if not Quit then
                    Find (Ss_List, Ss_Name, Ss_Ptr, Succeed);
                    Start_Walk (Ss_Ptr.Element_List);

                    loop
                        Walk (Ss_Ptr.Element_List, El_Ptr, End_List);
                        exit when End_List;
                        Fix_El_Size (El_Ptr);
                    end loop;
                end if;

            when 5 =>
                exit;

            when others =>
                null;
        end case;

    end loop;
end Update_Current;