DataMuseum.dk

top - metrics - download

    Length: 4225 (0x1081)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Accept_Statement
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --====================================================================
    -- Accept_Statement ::=
    --   "ACCEPT" <IDENTIFIER> [ Accept_Statement_Continued ]
    --   [ "DO" Sequence_Of_Statements "END" [ <IDENTIFIER> ] ] ";"
    --====================================================================

    Current_Token : Token_Package.Token;

begin
    -- Accept_Statement

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Accept_Token) then
        raise Syntax_Error;
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Class_Of (Current_Token),
             Token_Package.Identifier) then
        raise Syntax_Error;
    end if;

    -- increment Halstead operand count
    Halstead.Store_Operand (Halstead_Operand.Definition
                               (Token_Package.Value_Of
                                   (This_Token => Current_Token)));

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Left_Parenthesis_Token then

        Accept_Statement_Continued
           (Current_Compilation_Unit => Current_Compilation_Unit,
            Program_Unit => Program_Unit,
            Halstead => Halstead,
            Loc => Loc,
            Mccabe => Mccabe);
    end if;

    case Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) is

        when Token_Package.Do_Token =>

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            -- increment Halstead ACCEPT_DO_END operator count
            Halstead.Store_Operator
               ((Kind => Halstead_Operator.Accept_Do_End_Halstead));

            Sequence_Of_Statements
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe);

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if "/=" (Token_Package.Value_Of (Current_Token),
                     Token_Package.End_Token) then
                raise Syntax_Error;
            end if;

            if Token_Package.Class_Of (Peek
                                          (From => Current_Compilation_Unit)) =
               Token_Package.Identifier then

                Get_Next_Token (Out_Token => Current_Token,
                                From => Current_Compilation_Unit,
                                Current_Loc => Loc);

                -- increment Halstead operand count
                Halstead.Store_Operand (Halstead_Operand.Definition
                                           (Token_Package.Value_Of
                                               (This_Token => Current_Token)));

            end if;

        when others =>
            -- increment Halstead ACCEPT operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Accept_Halstead));

    end case;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Accept_Statement;