DataMuseum.dk

top - metrics - download

    Length: 2762 (0xaca)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

-- PERFORMANCE MEASUREMENT : Measure the time to do an unchecked
--                           conversion of one integer object to
--                           another.

with Unchecked_Conversion;
with Remote_Global;
use Remote_Global; -- control optimization
with Iteration; -- obtain stable measurement
with Piwg_Io; -- output results

procedure H000005 is  -- main procedure to execute

    Cpu_Time : Duration; -- CPU time for one feature execution
    Wall_Time : Duration; -- WALL time for one feature execution
    Check_Times : constant := 100; -- inside loop count and check
    Iteration_Count : Integer; -- set and varied by ITERATION package
    Stable : Boolean; -- true when measurement stable

    type Integer_1 is new Integer;
    type Integer_2 is new Integer;
    function Move is new Unchecked_Conversion (Integer_2, Integer_1);
    I_1 : Integer_1;
    I_2 : Integer_2;

begin

    Iteration.Start_Control;  -- dummy to bring in pages on some machines

    delay 0.5;  -- wait for stable enviornment on some machines

    Iteration.Initialize (Iteration_Count);

    loop  -- until stable measurement, ITERATION_COUNT increases each time

--
-- Control loop
--
        Iteration.Start_Control;
        for J in 1 .. Iteration_Count loop
            Global := 0;
            for Inside_Loop in 1 .. Check_Times loop
                Global := Global + A_One; -- prevent optimization
                Remote;
                I_2 := Integer_2 (Global);
                I_1 := Integer_1 (I_2);
                if Integer_2 (I_1) /= I_2 then
                    raise Program_Error; -- incorrect code
                end if;
            end loop;
        end loop;
        Iteration.Stop_Control (Global, Check_Times);

--
-- Test loop
--
        Iteration.Start_Test;
        for J in 1 .. Iteration_Count loop
            Global := 0;
            for Inside_Loop in 1 .. Check_Times loop
                Global := Global + A_One; -- prevent optimization
                Remote;
                I_2 := Integer_2 (Global);
                I_1 := Move (I_2);
                if Integer_2 (I_1) /= I_2 then -- check that code worked
                    raise Program_Error; -- incorrect code
                end if;
            end loop;
        end loop;
        Iteration.Stop_Test (Global, Check_Times);
        Iteration.Test_Stable (Iteration_Count, Stable);
        exit when Stable;
    end loop;
--
    Iteration.Feature_Times (Cpu_Time, Wall_Time);

--
-- Printout
--
    Piwg_Io.Piwg_Output
       ("H000005", "Chapter 13", Cpu_Time, Wall_Time, Iteration_Count,
        " The time for UNCHECKED_CONVERSION to move one INTEGER",
        " object to another INTEGER object",
        " This may be zero with good optimization.");

end H000005;