DataMuseum.dk

top - metrics - download

    Length: 2392 (0x958)
    Types: TextFile
    Names: »B«

└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─⟦129cab021⟧ »DATA« 
        └─⟦this⟧ 

TextFile

with Expression, More_Statements;
with Class_Printer;
with Bug_Report;

package body Statements is

    type Node_Structure is
        record
            Rule : Natural range 0 .. 2 := 0;
            Expr : Expression.Node := Expression.Empty_Node;
            More : More_Statements.Node := More_Statements.Empty_Node;
            Line : Object.Index := Scanner.Get_Line_Number;
        end record;

    procedure Parse (N : in out Node) is
        use Scanner;
    begin  
        N := new Node_Structure;
        if Expression.Is_First (Scanner.Get_Token) then
            N.Rule := 1;
            Expression.Parse (N.Expr);
            More_Statements.Parse (N.More);
        else
            case Scanner.Get_Token is
                when Scanner.Renvoyer =>
                    N.Rule := 2;
                    Scanner.Next;
                    Expression.Parse (N.Expr);
                when others =>
                    if not (Scanner.Get_Token = Scanner.Eof or else
                            Scanner.Get_Token = Scanner.Close_Brace) then
                        raise Bug_Report.Unexpected_Token;  
                    end if;
            end case;
        end if;  
    end Parse;

    function Is_First (T : Scanner.Token) return Boolean is
        use Scanner;
    begin
        return T = Renvoyer or else Expression.Is_First (T);
    end Is_First;

    procedure Unparse (N : Node) is
    begin
        case N.Rule is
            when 0 =>
                null;
            when 1 =>
                Expression.Unparse (N.Expr);
                More_Statements.Unparse (N.More);
            when 2 =>
                Class_Printer.Put_Tab ("renvoyer ");
                Expression.Unparse (N.Expr);
        end case;

    end Unparse;
    function Interpret (N : Node;
                        Inherited : Object.Reference := Object.Void_Reference)
                       return Object.Reference is
        Result : Object.Reference;
    begin  
        Scanner.Put_Line_Number (N.Line);
        case N.Rule is
            when 0 =>
                Result := Inherited;
            when 1 =>
                Result := Expression.Interpret (N.Expr);
                Result := More_Statements.Interpret (N.More, Result);
            when 2 =>
                Result := Expression.Interpret (N.Expr);
        end case;
        return Result;
    end Interpret;

end Statements;