DataMuseum.dk

top - metrics - download

    Length: 2621 (0xa3d)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Formal_Part (Current_Compilation_Unit : in out Ada_Compilation_Unit;
                       Program_Unit : in Program_Unit_State_Machine;
                       Halstead : in Halstead_State_Machine;
                       Loc : in Loc_State_Machine;
                       Mccabe : in Mccabe_State_Machine;
                       Formal_Parameters_Count : out Natural) is

    --=======================================================================
    -- Formal_Part returns number of parameters.
    -- Formal_Part ::=
    --   "(" Parameter_Specification { ";" Parameter_Specification } ")"
    --=======================================================================


    Current_Token : Token_Package.Token;
    Is_Right_Parenthesis_Found : Boolean := False;
    Increment : Natural := 0;
    Hold_Count : Natural := 0;

begin
    -- Formal_Part

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Left_Parenthesis_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead PARENTHESES operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Parentheses_Halstead));

    Find_Right_Parenthesis:
        loop

            Parameter_Specification
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe,
                Parameters_Count => Increment);

            Hold_Count := Hold_Count + Increment;

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            case Token_Package.Value_Of (Current_Token) is

                when Token_Package.Semicolon_Token =>
                    -- iterate

                    -- increment Halstead SEMICOLON operator count
                    Halstead.Store_Operator
                       ((Kind => Halstead_Operator.Semicolon_Halstead));

                when Token_Package.Right_Parenthesis_Token =>
                    Is_Right_Parenthesis_Found := True;

                when others =>
                    raise Syntax_Error;

            end case;

            exit Find_Right_Parenthesis when Is_Right_Parenthesis_Found;

        end loop Find_Right_Parenthesis;

    Formal_Parameters_Count := Hold_Count;

end Formal_Part;