DataMuseum.dk

top - metrics - download

    Length: 2128 (0x850)
    Types: TextFile
    Names: »B«

└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─⟦129cab021⟧ »DATA« 
        └─⟦this⟧ 

TextFile

with Broker;
with Errors;
with Trace;
with Unary;
with Unparser;

package body More_Binary is

    type Node_Structure is
        record
            Line : Natural;
            Rule : Natural range 0 .. 1 := 0;
            Binm : Scanner.Lexeme;
            Unar : Unary.Node := Unary.Empty_Node;
            More : Node := Empty_Node;
        end record;

    procedure Parse (N : in out Node) is
    begin
        Trace.Display ("parsing More_Binary");
        N := new Node_Structure;
        N.Line := Scanner.Get_Line_Number;
        case Scanner.Get_Token is
            when Scanner.L_Binm =>
                N.Rule := 1;
                N.Binm := Scanner.Get_Value;
                Scanner.Next_Token;
                if Unary.Is_First (Scanner.Get_Token) then
                    Unary.Parse (N.Unar);
                    Parse (N.More);
                else
                    raise Errors.Expecting_Unary_After_Binary_Message;
                end if;
            when others =>
                null;
        end case;
    end Parse;

    procedure Unparse (N : Node) is
    begin
        case N.Rule is
            when 0 =>
                null;
            when 1 =>
                Unparser.Put (N.Binm);
                Unparser.Put (" ");
                Unary.Unparse (N.Unar);
                More_Binary.Unparse (N.More);
        end case;
        Trace.Display ("fin unparse more_binary");
    end Unparse;

    function Interpret (N : Node;
                        Inherited : Object.Reference := Object.Void_Reference)
                       return Object.Reference is
        Result : Object.Reference;
    begin
        Errors.Save_Interpret_Line (N.Line);
        case N.Rule is
            when 0 =>
                Result := Inherited;
            when 1 =>
                Result := Unary.Interpret (N.Unar);
                Result := Broker.Send (Inherited, N.Binm, Result);
                Result := Interpret (N.More, Result);
        end case;
        Trace.Display ("fin interpretation More_Binary");
        Trace.Display (Result);
        return Result;
    end Interpret;

end More_Binary;