DataMuseum.dk

top - metrics - download

    Length: 3072 (0xc00)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Component_Declaration
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --=========================================================
    -- Component_Declaration ::=
    --   ID_List ":" Subtype_Indication [ ":=" Expression ] ";"
    --=========================================================

    Current_Token : Token_Package.Token;
    Number_Of_Identifiers : Positive;

begin
    -- Component_Declaration

    Id_List (Current_Compilation_Unit => Current_Compilation_Unit,
             Program_Unit => Program_Unit,
             Halstead => Halstead,
             Loc => Loc,
             Mccabe => Mccabe,
             Number_Of_Identifiers => Number_Of_Identifiers);

    -- change LOC data declaration count by Number_Of_IDENTIFIERs
    Loc.Change_Data_Declarations_Count
       (The_Amount_To_Change => Number_Of_Identifiers);

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Colon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead COLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Colon_Halstead));

    Subtype_Indication (Current_Compilation_Unit => Current_Compilation_Unit,
                        Program_Unit => Program_Unit,
                        Halstead => Halstead,
                        Loc => Loc,
                        Mccabe => Mccabe);

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Assignment_Token then

        Get_Next_Token (Out_Token => Current_Token,
                        From => Current_Compilation_Unit,
                        Current_Loc => Loc);

        -- increment Halstead ASSIGNMENT operator count
        Halstead.Store_Operator ((Kind =>
                                     Halstead_Operator.Assignment_Halstead));

        -- until ";" is found
        Expression (Current_Compilation_Unit => Current_Compilation_Unit,
                    Program_Unit => Program_Unit,
                    Halstead => Halstead,
                    Loc => Loc,
                    Mccabe => Mccabe,
                    Terminate_Tokens =>
                       Set_Of_Tokens'(1 => Token_Package.Semicolon_Token));
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Component_Declaration;