|
DataMuseum.dkPresents historical artifacts from the history of: Rational R1000/400 Tapes |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about Rational R1000/400 Tapes Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - downloadIndex: B T
Length: 8197 (0x2005)
Types: TextFile
Names: »B«
└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
└─⟦5cb1d1d7f⟧ »DATA«
└─⟦3b1ee7bd8⟧
└─⟦this⟧
separate (Compilation_Unit.Produce_Metrics)
procedure Proper_Body (Current_Compilation_Unit : in out Ada_Compilation_Unit;
Program_Unit : in Program_Unit_State_Machine;
Halstead : in Halstead_State_Machine;
Loc : in Loc_State_Machine;
Mccabe : in Mccabe_State_Machine) is
--===================================================================
-- Proper_Body ::=
-- Count number of parameters in formal part.
-- Program unit is PROCEDURE_BODY
-- Procedure_Specification "IS" Common_Body [ <IDENTIFIER> ] ";"
-- count number of parameters in formal part.
-- Program unit is FUNCTION_BODY.
-- | Function_Specification "IS" Common_Body [ Designator ] ";"
-- 5th token can not be "SEPARATE"
-- | Package_Body
-- 5th token can not be "SEPARATE"
-- | Task_Body
--===================================================================
Current_Token : Token_Package.Token;
Unit_Name : Program_Unit_Name;
Dummy_Name : Program_Unit_Name;
Parameters_Count : Natural;
begin
-- Proper_Body
case Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) is
when Token_Package.Procedure_Token =>
-- set program unit to PROCEDURE_BODY
Program_Unit.Store_Kind_Of_Program_Unit
(The_Kind_Of_Program_Unit => Procedure_Body);
-- increment Halstead PROCEDURE_IS operator count
Halstead.Store_Operator
((Kind => Halstead_Operator.Procedure_Is_Halstead));
Procedure_Specification
(Current_Compilation_Unit => Current_Compilation_Unit,
Program_Unit => Program_Unit,
Halstead => Halstead,
Loc => Loc,
Mccabe => Mccabe,
Unit_Name => Unit_Name,
Formal_Parameters_Count => Parameters_Count);
-- set program unit name
Program_Unit.Store_Program_Unit_Name
(The_Program_Unit_Name => Unit_Name);
--** changed 11/20/85 by J. Margono
--** reason: Constraint_Error was raised if Parameters_Count = 0
if Parameters_Count > 0 then
-- change parameters count
Halstead.Change_Parameters_Count
(The_Amount_To_Change => Parameters_Count);
end if;
Get_Next_Token (Out_Token => Current_Token,
From => Current_Compilation_Unit,
Current_Loc => Loc);
if "/=" (Token_Package.Value_Of (Current_Token),
Token_Package.Is_Token) then
raise Syntax_Error;
end if;
Common_Body (Current_Compilation_Unit => Current_Compilation_Unit,
Program_Unit => Program_Unit,
Halstead => Halstead,
Loc => Loc,
Mccabe => Mccabe);
Get_Next_Token (Out_Token => Current_Token,
From => Current_Compilation_Unit,
Current_Loc => Loc);
if Token_Package.Class_Of (Current_Token) =
Token_Package.Identifier then
-- increment Halstead operand count
Halstead.Store_Operand (Halstead_Operand.Definition
(Token_Package.Value_Of
(This_Token => Current_Token)));
Get_Next_Token (Out_Token => Current_Token,
From => Current_Compilation_Unit,
Current_Loc => Loc);
end if;
if "/=" (Token_Package.Value_Of (Current_Token),
Token_Package.Semicolon_Token) then
raise Syntax_Error;
end if;
-- increment Halstead SEMICOLON operator count
Halstead.Store_Operator ((Kind =>
Halstead_Operator.Semicolon_Halstead));
when Token_Package.Function_Token =>
-- set program unit to FUNCTION_BODY
Program_Unit.Store_Kind_Of_Program_Unit
(The_Kind_Of_Program_Unit => Function_Body);
-- increment Halstead FUNCTION_IS operator count
Halstead.Store_Operator
((Kind => Halstead_Operator.Function_Is_Halstead));
Function_Specification
(Current_Compilation_Unit => Current_Compilation_Unit,
Program_Unit => Program_Unit,
Halstead => Halstead,
Loc => Loc,
Mccabe => Mccabe,
Unit_Name => Unit_Name,
Formal_Parameters_Count => Parameters_Count);
-- set program unit name
Program_Unit.Store_Program_Unit_Name
(The_Program_Unit_Name => Unit_Name);
--** added 11/20/85 by J. Margono
--** reason: was not present
if Parameters_Count > 0 then
-- change parameters count
Halstead.Change_Parameters_Count
(The_Amount_To_Change => Parameters_Count);
end if;
Get_Next_Token (Out_Token => Current_Token,
From => Current_Compilation_Unit,
Current_Loc => Loc);
if "/=" (Token_Package.Value_Of (Current_Token),
Token_Package.Is_Token) then
raise Syntax_Error;
end if;
Common_Body (Current_Compilation_Unit => Current_Compilation_Unit,
Program_Unit => Program_Unit,
Halstead => Halstead,
Loc => Loc,
Mccabe => Mccabe);
if "/=" (Token_Package.Value_Of
(Peek (From => Current_Compilation_Unit)),
Token_Package.Semicolon_Token) then
Designator (Current_Compilation_Unit =>
Current_Compilation_Unit,
Program_Unit => Program_Unit,
Halstead => Halstead,
Loc => Loc,
Mccabe => Mccabe,
Unit_Name => Dummy_Name);
end if;
Get_Next_Token (Out_Token => Current_Token,
From => Current_Compilation_Unit,
Current_Loc => Loc);
if "/=" (Token_Package.Value_Of (Current_Token),
Token_Package.Semicolon_Token) then
raise Syntax_Error;
end if;
-- increment Halstead SEMICOLON operator count
Halstead.Store_Operator ((Kind =>
Halstead_Operator.Semicolon_Halstead));
when Token_Package.Package_Token =>
-- can NOT be a stub
if Token_Package.Value_Of
(Peek (From => Current_Compilation_Unit, Offset => 5)) =
Token_Package.Separate_Token then
raise Syntax_Error;
end if;
Package_Body (Current_Compilation_Unit => Current_Compilation_Unit,
Program_Unit => Program_Unit,
Halstead => Halstead,
Loc => Loc,
Mccabe => Mccabe);
when Token_Package.Task_Token =>
-- can NOT be a stub
if Token_Package.Value_Of
(Peek (From => Current_Compilation_Unit, Offset => 5)) =
Token_Package.Separate_Token then
raise Syntax_Error;
end if;
Task_Body (Current_Compilation_Unit => Current_Compilation_Unit,
Program_Unit => Program_Unit,
Halstead => Halstead,
Loc => Loc,
Mccabe => Mccabe);
when others =>
raise Syntax_Error;
end case;
end Proper_Body;