DataMuseum.dk

top - metrics - download

    Length: 6986 (0x1b4a)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Package_Body (Current_Compilation_Unit : in out Ada_Compilation_Unit;
                        Program_Unit : in Program_Unit_State_Machine;
                        Halstead : in Halstead_State_Machine;
                        Loc : in Loc_State_Machine;
                        Mccabe : in Mccabe_State_Machine) is

    --===============================================================
    -- Package_Body ::=
    --     "PACKAGE" "BODY" <IDENTIFIER> "IS"
    --     ( [ Declarative_Part ]
    --       ( BEGIN_END_Block | "END" ) [ <IDENTIFIER> ]
    --     | "SEPARATE" )  ";"
    --===============================================================

    Current_Token : Token_Package.Token;
    Unit_Name : Program_Unit_Name;

begin
    -- Package_Body

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Package_Token) then
        raise Syntax_Error;
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Body_Token) then
        raise Syntax_Error;
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Class_Of (Current_Token),
             Token_Package.Identifier) then
        raise Syntax_Error;
    end if;

    -- convert Token_Value to Program_Unit_Name
    Unit_Name := String_To_Name (Token_Package.Value_Of (Current_Token));

    -- set program unit name
    Program_Unit.Store_Program_Unit_Name (The_Program_Unit_Name => Unit_Name);

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Is_Token) then
        raise Syntax_Error;
    end if;

    case Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) is

        when Token_Package.Separate_Token =>
            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            -- set program unit kind to PACKAGE_BODY_STUB
            Program_Unit.Store_Kind_Of_Program_Unit
               (The_Kind_Of_Program_Unit => Package_Body_Stub);

            -- increment Halstead PACKAGE_BODY_IS operator
            Halstead.Store_Operator
               ((Kind => Halstead_Operator.Package_Body_Is_Halstead));

            -- increment Halstead SEPARATE operator
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Separate_Halstead));

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

        when others =>
            Declarative_Part
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe);

            case Token_Package.Value_Of
                    (Peek (From => Current_Compilation_Unit)) is

                when Token_Package.Begin_Token =>

                    -- set program unit kind to PACKAGE_BODY
                    Program_Unit.Store_Kind_Of_Program_Unit
                       (The_Kind_Of_Program_Unit => Package_Body);

                    -- increment Halstead PACKAGE_BODY_IS operator count
                    Halstead.Store_Operator
                       ((Kind => Halstead_Operator.Package_Body_Is_Halstead));

                    Begin_End_Block
                       (Current_Compilation_Unit => Current_Compilation_Unit,
                        Program_Unit => Program_Unit,
                        Halstead => Halstead,
                        Loc => Loc,
                        Mccabe => Mccabe);

                    Get_Next_Token (Out_Token => Current_Token,
                                    From => Current_Compilation_Unit,
                                    Current_Loc => Loc);

                    if Token_Package.Class_Of (Current_Token) =
                       Token_Package.Identifier then

                        -- increment Halstead operand count
                        Halstead.Store_Operand
                           (Halstead_Operand.Definition
                               (Token_Package.Value_Of
                                   (This_Token => Current_Token)));

                        Get_Next_Token (Out_Token => Current_Token,
                                        From => Current_Compilation_Unit,
                                        Current_Loc => Loc);
                    end if;

                when Token_Package.End_Token =>

                    Get_Next_Token (Out_Token => Current_Token,
                                    From => Current_Compilation_Unit,
                                    Current_Loc => Loc);

                    -- set program unit kind to PACKAGE_BODY
                    Program_Unit.Store_Kind_Of_Program_Unit
                       (The_Kind_Of_Program_Unit => Package_Body);

                    -- increment Halstead PACKAGE_BODY_IS_END operator count
                    Halstead.Store_Operator
                       ((Kind => Halstead_Operator.
                                    Package_Body_Is_End_Halstead));

                    Get_Next_Token (Out_Token => Current_Token,
                                    From => Current_Compilation_Unit,
                                    Current_Loc => Loc);

                    if Token_Package.Class_Of (Current_Token) =
                       Token_Package.Identifier then

                        -- increment Halstead operand count
                        Halstead.Store_Operand
                           (Halstead_Operand.Definition
                               (Token_Package.Value_Of
                                   (This_Token => Current_Token)));

                        Get_Next_Token (Out_Token => Current_Token,
                                        From => Current_Compilation_Unit,
                                        Current_Loc => Loc);
                    end if;

                when others =>
                    raise Syntax_Error;

            end case;

    end case;

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Package_Body;