DataMuseum.dk

top - metrics - download

    Length: 2778 (0xada)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Find_Unit.Build_Ada_Compilation_Unit)
procedure Left_Right_Paren (Current_Unit : in out
                               Compilation_Unit.Ada_Compilation_Unit) is
    --==============================================================
    -- This procedure builds the next part of the grammar for an   =
    -- Ada compilation unit. Based on the next token, we will      =
    -- complete different productions. At present, we are parsing  =
    -- a left parenthesis and looking for a right parenthesis. If  =
    -- a left parenthesis is found before the corresponding right  =
    -- parenthesis, then we will recurse on this procedure.        =
    -- If we find a syntax error, then we will raise the exception =
    -- Build_Syntax_Error.                                         =
    -- The grammar :                                               =
    --      <Left_Right_Paren> =                                   =
    --'(' <Inside_Left_Right_Paren> {<Inside_Left_Right_Paren>} ')'=
    --                                                             =
    -- written  by  GER  with  help  from  b2  and  JM             =
    -- May 1985  at EVB Software Engineering                       =
    --==============================================================

    Current_Token : Token_Package.Token;
    -- Holds the current token
    Peek_Token : Token_Package.Token;
    -- This will token will be looked later

begin
    -- Left_Right_Paren

    -- Parse a left parenthesis, then a right parenthesis

    Get_Next_Significant_Token (Significant_Token => Current_Token,
                                Current_Unit => Current_Unit);

    if Token_Package.Value_Of (Current_Token) =
       Token_Package.Left_Parenthesis_Token then
        Compilation_Unit.Add_Token_To_Compilation_Unit
           (Token_To_Add => Current_Token, Unit_To_Add_To => Current_Unit);
    else
        -- Not a left parenthesis
        raise Build_Syntax_Error;
    end if;

    Inside_Left_Right_Paren (Current_Unit => Current_Unit);

    -- Repeatly parse tokens until the right paren is found

    Find_Right_Paren:
        loop
            Peek_Next_Significant_Token (Significant_Token => Peek_Token);

            exit Find_Right_Paren when Token_Package.Value_Of (Peek_Token) =
                                          Token_Package.Right_Parenthesis_Token;

            Inside_Left_Right_Paren (Current_Unit => Current_Unit);

        end loop Find_Right_Paren;

    -- Parse a right parenthesis

    Get_Next_Significant_Token (Significant_Token => Current_Token,
                                Current_Unit => Current_Unit);
    Compilation_Unit.Add_Token_To_Compilation_Unit
       (Token_To_Add => Current_Token, Unit_To_Add_To => Current_Unit);

end Left_Right_Paren;