DataMuseum.dk

top - metrics - download

    Length: 3812 (0xee4)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Conditional_Or_Timed_Entry_Call
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --===================================================================
    -- Conditional_Or_Timed_Entry_Call ::=
    --      Name ";"
    --      [ Sequence_Of_Statements ]
    --      ( "ELSE" Sequence_Of_Statements |
    --        "OR"   Pragma_Clause Delay_Alternative Pragma_Clause )
    --===================================================================

    Dummy_Name_Kind : Name_Kind;
    Current_Token : Token_Package.Token;

begin
    -- Conditional_Or_Timed_Entry_Call

    Name (Current_Compilation_Unit => Current_Compilation_Unit,
          Program_Unit => Program_Unit,
          Halstead => Halstead,
          Loc => Loc,
          Mccabe => Mccabe,
          Out_Name_Kind => Dummy_Name_Kind);

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

    case Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) is

        when Token_Package.Or_Token | Token_Package.Else_Token =>
            null; -- no Sequence_Of_Statements

        when others =>
            Sequence_Of_Statements
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe);

    end case;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    case Token_Package.Value_Of (Current_Token) is

        when Token_Package.Else_Token =>
            -- increment Halstead ELSE operator count
            Halstead.Store_Operator ((Kind => Halstead_Operator.Else_Halstead));

            -- increment McCabe PI
            Mccabe.Change_Pi;

            Sequence_Of_Statements
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe);

        when Token_Package.Or_Token =>
            -- increment Halstead OR operator count
            Halstead.Store_Operator ((Kind => Halstead_Operator.Or_Halstead));

            -- increment McCabe PI
            Mccabe.Change_Pi;

            Pragma_Clause (Current_Compilation_Unit => Current_Compilation_Unit,
                           Program_Unit => Program_Unit,
                           Halstead => Halstead,
                           Loc => Loc,
                           Mccabe => Mccabe);

            Delay_Alternative
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe);

            Pragma_Clause (Current_Compilation_Unit => Current_Compilation_Unit,
                           Program_Unit => Program_Unit,
                           Halstead => Halstead,
                           Loc => Loc,
                           Mccabe => Mccabe);

        when others =>
            raise Syntax_Error;

    end case;

end Conditional_Or_Timed_Entry_Call;