DataMuseum.dk

top - metrics - download

    Length: 2792 (0xae8)
    Types: TextFile
    Names: »V«

└─⟦149519bd4⟧ Bits:30000546 8mm tape, Rational 1000, !projects 93-07-13
    └─⟦124ff5788⟧ »DATA« 
        └─⟦this⟧ 
└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─⟦129cab021⟧ »DATA« 
        └─⟦this⟧ 
└─⟦f64eaa120⟧ Bits:30000752 8mm tape, Rational 1000, !projects 93 02 16
    └─⟦6f12a12be⟧ »DATA« 
        └─⟦this⟧ 
└─⟦2f6cfab89⟧ Bits:30000547 8mm tape, Rational 1000, !projects 94-01-04
    └─⟦d65440be7⟧ »DATA« 
        └─⟦this⟧ 

TextFile

-------------------------------------------------------------------------------
generic  
    Max_Size : Positive;
    type Element is private;

package Static_List_Generic is
    type Object is private;

    function Null_Object return Object;


    function Add (X : Element; Into : Object) return Object;
    -- can raise Full_Error


    function Is_Empty (The_Object : Object) return Boolean;
    -- used to avoid raising the Empty_Error exception

    function Is_Full (The_Object : Object) return Boolean;
    -- used to avoid raising the Full_Error exception

    function First (The_Object : Object) return Element;
    function Rest  (The_Object : Object) return Object;
    -- can raise Empty_Error

    generic
        with function Is_Equal (Left, Right : Element) return Boolean;
    function Is_Equal (Left, Right : Object) return Boolean;

    function Length (The_Object : Object) return Natural;

    generic
        with function Is_Equal (Left, Right : Element) return Boolean;
    function Is_Element
                (The_Element : Element; Of_The_Object : Object) return Boolean;


    procedure Set_Rest (The_Object : in out Object; To_Be : Object);
    -- can raise Empty_Error or Full_Error
    procedure Set_First (The_Object : in out Object; To_Be : Element);
    -- can raise Empty_Error

    Full_Error  : exception;
    Empty_Error : exception;

    generic
        with function "<" (Left, Right : Element) return Boolean;
    procedure Sort (The_Object : in out Object);

    procedure Free (The_Object : in out Object);
    -- make The_Object empty


    type Iterator is private;

    procedure Init  (Iter : out Iterator; The_Object : Object);
    procedure Next  (Iter : in out Iterator; The_Object : Object);
    function  Value (Iter : Iterator; The_Object : Object) return Element;
    function  Done  (Iter : Iterator; The_Object : Object) return Boolean;


    generic  
        Separator : String;
        with function Image (The_Element : Element) return String;
    function Image (The_Object : Object) return String;

    generic
        with procedure Display (The_Element : Element; String_Before : String);
    procedure Display (The_Object : Object; String_Before : String := "");

-------------------------------------------------------------------------------
private
    subtype Index is Positive range 1 .. Max_Size;
    type    Table is array (Index range <>) of Element;

    type Object is
        record
            The_Table : Table (Index);  
            Size      : Natural := 0;
        end record;

    type Iterator is
        record  
            Index_Value : Index;
            Done        : Boolean;
        end record;
end Static_List_Generic;
-------------------------------------------------------------------------------