DataMuseum.dk

Presents historical artifacts from the history of:

Rational R1000/400 Tapes

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Rational R1000/400 Tapes

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download
Index: B T

⟦d1b932a6d⟧ TextFile

    Length: 2540 (0x9ec)
    Types: TextFile
    Names: »B«

Derivation

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Selective_Wait
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --=================================================
    -- Selective_Wait ::=
    --     Select_Alternative
    --     { "OR" Select_Alternative }
    --     [ "ELSE" Sequence_Of_Statements ]
    --=================================================

    Current_Token : Token_Package.Token;
    Peek_Ahead_Token : Token_Package.Token;
    Is_Done : Boolean := False;

begin
    -- Selective_Wait

    Select_Alternative (Current_Compilation_Unit => Current_Compilation_Unit,
                        Program_Unit => Program_Unit,
                        Halstead => Halstead,
                        Loc => Loc,
                        Mccabe => Mccabe);

    Process_Select_Alternatives:
        while Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
                 Token_Package.Or_Token loop

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            -- increment Halstead OR operator count
            Halstead.Store_Operator ((Kind => Halstead_Operator.Or_Halstead));

            -- increment McCabe PI
            Mccabe.Change_Pi;

            Select_Alternative
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe);

        end loop Process_Select_Alternatives;

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Else_Token then

        Get_Next_Token (Out_Token => Current_Token,
                        From => Current_Compilation_Unit,
                        Current_Loc => Loc);

        -- increment Halstead ELSE operator count
        Halstead.Store_Operator ((Kind => Halstead_Operator.Else_Halstead));

        -- increment McCabe PI
        Mccabe.Change_Pi;

        Sequence_Of_Statements
           (Current_Compilation_Unit => Current_Compilation_Unit,
            Program_Unit => Program_Unit,
            Halstead => Halstead,
            Loc => Loc,
            Mccabe => Mccabe);

    end if;

end Selective_Wait;