DataMuseum.dk

Presents historical artifacts from the history of:

Rational R1000/400 Tapes

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Rational R1000/400 Tapes

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download
Index: T V

⟦de3b98924⟧ TextFile

    Length: 2051 (0x803)
    Types: TextFile
    Names: »V«

Derivation

└─⟦bfaa708f6⟧ Bits:30000531 8mm tape, Rational 1000, INSIGHT 1_3_0
    └─⟦c51948655⟧ »DATA« 
        └─⟦266b31e86⟧ 
            └─⟦this⟧

TextFile

package Screen is

    type Panel is limited private;

    type State is (Off, On);


    type Display_Item is (Weather, Flight_Info, Reservations, Stock_Market,
                          Call, Redial, Modem, Light_On, Light_Off,
                          Service_Call, Audio_Channel, Game, Movie,
                          Smoking_Permitted, Seat_Belt_Required, Seat_Number);

    subtype Display_Item_With_Label is Display_Item range Weather .. Movie;
    subtype Display_Item_With_Value is
       Display_Item range Light_On .. Seat_Number;

    subtype Display_Item_With_Passenger_Choices is
       Display_Item range Audio_Channel .. Movie;

    subtype Passenger_Choice_List is String;
    -- Choices in a list are separated by commas.
    subtype Passenger_Choice is String;

    procedure Create (The_Panel : in out Panel);

    function Get_Selection (The_Panel : Panel) return Display_Item_With_Label;

    procedure Set_Light (To_State : State; On_The_Panel : Panel);

    procedure Set_Service_Call (To_State : State; On_The_Panel : Panel);


    function Get_Choice (For_Item : Display_Item_With_Passenger_Choices;
                         From_List : Passenger_Choice_List;
                         On_The_Panel : Panel) return Passenger_Choice;

    procedure Close (The_Panel : in out Panel);

private
    type Key is new Natural range 0 .. 1023;  -- Keyboard key

    task type Panel_Manager is

        entry Start;

        entry Get (User_Input : out Key);

        entry Get_Current_Highlighted (Item : out Display_Item_With_Label);

        entry Highlight (Item : Display_Item_With_Label);

        entry Set_Light (To_State : State);

        entry Set_Service_Call (To_State : State);

        entry Get_Choice (For_Item : Display_Item_With_Passenger_Choices;
                          From_List : Passenger_Choice_List;
                          Choice_Number : out Positive);

        entry Kill;

    end Panel_Manager;

    type Panel is
        record
            Manager : Panel_Manager;
        end record;
end Screen;