DataMuseum.dk

top - metrics - download

    Length: 4012 (0xfac)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Parameter_Specification
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine;
              Parameters_Count : out Natural) is

    --===================================================================
    -- Parameter_Specification ::=
    --   ID_List ":" [ "IN" ] [ "OUT" ] Expanded_Name [ ":=" Expression ]
    --===================================================================

    Current_Token : Token_Package.Token;

begin
    -- Parameter_Specification

    Id_List (Current_Compilation_Unit => Current_Compilation_Unit,
             Program_Unit => Program_Unit,
             Halstead => Halstead,
             Loc => Loc,
             Mccabe => Mccabe,
             Number_Of_Identifiers => Parameters_Count);

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Colon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead COLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Colon_Halstead));

    case Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) is

        when Token_Package.In_Token =>
            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if Token_Package.Value_Of (Peek
                                          (From => Current_Compilation_Unit)) =
               Token_Package.Out_Token then

                Get_Next_Token (Out_Token => Current_Token,
                                From => Current_Compilation_Unit,
                                Current_Loc => Loc);

                -- increment Halstead IN_OUT operator count
                Halstead.Store_Operator
                   ((Kind => Halstead_Operator.In_Out_Halstead));
            else

                -- increment Halstead IN operator count
                Halstead.Store_Operator ((Kind =>
                                             Halstead_Operator.In_Halstead));
            end if;

        when Token_Package.Out_Token =>

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            -- increment Halstead OUT operator count
            Halstead.Store_Operator ((Kind => Halstead_Operator.Out_Halstead));

        when others =>
            null;

    end case;

    Expanded_Name (Current_Compilation_Unit => Current_Compilation_Unit,
                   Program_Unit => Program_Unit,
                   Halstead => Halstead,
                   Loc => Loc,
                   Mccabe => Mccabe);

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Assignment_Token then

        Get_Next_Token (Out_Token => Current_Token,
                        From => Current_Compilation_Unit,
                        Current_Loc => Loc);

        -- increment Halstead ASSIGNMENT operator count
        Halstead.Store_Operator ((Kind =>
                                     Halstead_Operator.Assignment_Halstead));

        -- until ";" or ")" is found
        Expression (Current_Compilation_Unit => Current_Compilation_Unit,
                    Program_Unit => Program_Unit,
                    Halstead => Halstead,
                    Loc => Loc,
                    Mccabe => Mccabe,
                    Terminate_Tokens =>
                       Set_Of_Tokens'(Token_Package.Right_Parenthesis_Token,
                                      Token_Package.Semicolon_Token));

    end if;

end Parameter_Specification;