DataMuseum.dk

top - metrics - download

    Length: 5104 (0x13f0)
    Types: TextFile
    Names: »B«

└─⟦180fe333a⟧ Bits:30000405 8mm tape, Rational 1000, SW CATALOG, 10_20_0
└─⟦180fe333a⟧ Bits:30000537 8mm tape, Rational 1000, SW Catalog 10_20_0
    └─⟦5cb1d1d7f⟧ »DATA« 
        └─⟦3b1ee7bd8⟧ 
            └─⟦this⟧ 

TextFile

separate (Compilation_Unit.Produce_Metrics)
procedure Simple_Clause_Continued
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --=======================================================
    -- Simple_Clause_Continued #::=
    --     Aggregate             -> "("
    --   | "RECORD"              -> "RECORD"
    --     Pragma_Clause
    --     [ Alignment_Clause Pragma_Clause ]
    --     { Component_Clause Pragma_Clause }
    --     "END" "RECORD"
    --   | "AT" Expression
    --=======================================================

    Current_Token : Token_Package.Token;
    Dummy_Count : Positive;

begin
    -- Simple_Clause_Continued

    case Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) is

        when Token_Package.Left_Parenthesis_Token =>
            Aggregate (Current_Compilation_Unit => Current_Compilation_Unit,
                       Program_Unit => Program_Unit,
                       Halstead => Halstead,
                       Loc => Loc,
                       Mccabe => Mccabe,
                       Number_Of_Components => Dummy_Count);

        when Token_Package.Record_Token =>
            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            Pragma_Clause (Current_Compilation_Unit => Current_Compilation_Unit,
                           Program_Unit => Program_Unit,
                           Halstead => Halstead,
                           Loc => Loc,
                           Mccabe => Mccabe);

            if Token_Package.Value_Of (Peek
                                          (From => Current_Compilation_Unit)) =
               Token_Package.At_Token then

                Alignment_Clause
                   (Current_Compilation_Unit => Current_Compilation_Unit,
                    Program_Unit => Program_Unit,
                    Halstead => Halstead,
                    Loc => Loc,
                    Mccabe => Mccabe);

                Pragma_Clause
                   (Current_Compilation_Unit => Current_Compilation_Unit,
                    Program_Unit => Program_Unit,
                    Halstead => Halstead,
                    Loc => Loc,
                    Mccabe => Mccabe);

            end if;

            Process_Component_Clauses:
                while "/=" (Token_Package.Value_Of
                               (Peek (From => Current_Compilation_Unit)),
                            Token_Package.End_Token) loop

                    Component_Clause
                       (Current_Compilation_Unit => Current_Compilation_Unit,
                        Program_Unit => Program_Unit,
                        Halstead => Halstead,
                        Loc => Loc,
                        Mccabe => Mccabe);

                    Pragma_Clause
                       (Current_Compilation_Unit => Current_Compilation_Unit,
                        Program_Unit => Program_Unit,
                        Halstead => Halstead,
                        Loc => Loc,
                        Mccabe => Mccabe);

                end loop Process_Component_Clauses;

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if "/=" (Token_Package.Value_Of (Current_Token),
                     Token_Package.End_Token) then
                raise Syntax_Error;
            end if;

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if "/=" (Token_Package.Value_Of (Current_Token),
                     Token_Package.Record_Token) then
                raise Syntax_Error;
            end if;

            -- increment Halstead RECORD_END_RECORD operator count
            Halstead.Store_Operator
               ((Kind => Halstead_Operator.Record_End_Record_Halstead));

        when Token_Package.At_Token =>
            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            -- increment Halstead AT operator count
            Halstead.Store_Operator ((Kind => Halstead_Operator.At_Halstead));

            -- until ";" is found
            Expression (Current_Compilation_Unit => Current_Compilation_Unit,
                        Program_Unit => Program_Unit,
                        Halstead => Halstead,
                        Loc => Loc,
                        Mccabe => Mccabe,
                        Terminate_Tokens =>
                           Set_Of_Tokens'(1 => Token_Package.Semicolon_Token));

        when others =>
            raise Syntax_Error;

    end case;

end Simple_Clause_Continued;